1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
|
------------------------------------------------------------------------------
-- --
-- GNAT RUN-TIME COMPONENTS --
-- --
-- GNAT.BINARY_SEARCH --
-- --
-- B o d y --
-- --
-- Copyright (C) 2022, AdaCore --
-- --
-- GNAT is free software; you can redistribute it and/or modify it under --
-- terms of the GNU General Public License as published by the Free Soft- --
-- ware Foundation; either version 3, or (at your option) any later ver- --
-- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
-- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
-- or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are granted --
-- additional permissions described in the GCC Runtime Library Exception, --
-- version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
------------------------------------------------------------------------------
package body GNAT.Binary_Search is
function Index
(First, Last, Start : Index_Type;
Element : Element_Type) return Index_Type'Base is
begin
if Leftmost then
declare
function Before
(Index : Index_Type; Element : Element_Type) return Boolean
is (Before (Get (Index), Element)) with Inline_Always;
function Find is new Binary_Search.Leftmost
(Index_Type, Element_Type, Before);
begin
return Find (First, Last, Start, Element);
end;
else
declare
function Before
(Element : Element_Type; Index : Index_Type) return Boolean
is (Before (Element, Get (Index))) with Inline_Always;
function Find is new Rightmost (Index_Type, Element_Type, Before);
begin
return Find (First, Last, Start, Element);
end;
end if;
end Index;
--------------
-- Leftmost --
--------------
function Leftmost
(First, Last, Start : Index_Type;
Element : Element_Type) return Index_Type'Base
is
L : Index_Type := First;
R : Index_Type := Index_Type'Succ (Last);
M : Index_Type := Start;
begin
if First <= Last then
loop
if Before (M, Element) then
L := Index_Type'Succ (M);
else
R := M;
end if;
exit when L >= R;
M := Index_Type'Val
(Index_Type'Pos (L) +
(Index_Type'Pos (R) - Index_Type'Pos (L)) / 2);
end loop;
end if;
return L;
end Leftmost;
---------------
-- Rightmost --
---------------
function Rightmost
(First, Last, Start : Index_Type;
Element : Element_Type) return Index_Type'Base
is
L : Index_Type := First;
R : Index_Type := Index_Type'Succ (Last);
M : Index_Type := Start;
begin
if First > Last then
return Last;
else
loop
if Before (Element, M) then
R := M;
else
L := Index_Type'Succ (M);
end if;
exit when L >= R;
M := Index_Type'Val
(Index_Type'Pos (L) +
(Index_Type'Pos (R) - Index_Type'Pos (L)) / 2);
end loop;
end if;
return Index_Type'Pred (R);
end Rightmost;
end GNAT.Binary_Search;
|
