[multiple changes]

2017-09-08  Bob Duff  <duff@adacore.com>

	* s-ststop.ads, s-ststop.adb, rtsfind.ads (String_Input_Tag):
	New routine to read the Tag robustly.
	* exp_attr.adb (Input): Change the expansion of 'Input,
	in the class-wide case, to call String_Input_Tag instead of
	String_Input_Blk_IO.

2017-09-08  Arnaud Charlet  <charlet@adacore.com>

	* s-rident.ads (Restriction_Id): reorder enum
	literals, so that Pure_Barriers is no longer in range of the
	Cunit_Boolean_Restrictions subtype.

2017-09-08  Nicolas Roche  <roche@adacore.com>

	* a-taster.ads, a-taster.adb: Move to libgnarl
	* gcc-interface/Makefile.in: Remove obsolete targets. Code cleanups.
	Add support for files in libgnarl.

2017-09-08  Ed Schonberg  <schonberg@adacore.com>

	* exp_ch4.adb (Expand_N_Type_Conversion): Do not apply
	accessibility check to an interface conversion, whose purpose
	is to perform a pointer adjustment in a dispatching call.
	* exp_ch6.adb (Expand_Call_JHelper): Add accessibility checks
	when the actual is a construct that involves a dereference of an
	expression that includes a formal of the enclosing subprogram,
	In such cases, the accessibility level of the actual is that of
	the corresponding formal, which is passed in as an additional
	actual in the outer call.

From-SVN: r251886

2 files changed, 230 insertions, 0 deletions

diff --git a/gcc/ada/libgnarl/a-taster.adb b/gcc/ada/libgnarl/a-taster.adb
new file mode 100644
index 0000000..c4b4aaa
--- /dev/null
+++ b/gcc/ada/libgnarl/a-taster.adb
@@ -0,0 +1,191 @@
+------------------------------------------------------------------------------
+--                                                                          --
+--                         GNAT RUN-TIME COMPONENTS                         --
+--                                                                          --
+--                 A D A . T A S K _ T E R M I N A T I O N                  --
+--                                                                          --
+--                                 B o d y                                  --
+--                                                                          --
+--          Copyright (C) 2005-2009, Free Software Foundation, Inc.         --
+--                                                                          --
+-- GNAT is free software;  you can  redistribute it  and/or modify it under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 3,  or (at your option) any later ver- --
+-- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
+-- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
+-- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
+--                                                                          --
+-- As a special exception under Section 7 of GPL version 3, you are granted --
+-- additional permissions described in the GCC Runtime Library Exception,   --
+-- version 3.1, as published by the Free Software Foundation.               --
+--                                                                          --
+-- You should have received a copy of the GNU General Public License and    --
+-- a copy of the GCC Runtime Library Exception along with this program;     --
+-- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
+-- <http://www.gnu.org/licenses/>.                                          --
+--                                                                          --
+-- GNAT was originally developed  by the GNAT team at  New York University. --
+-- Extensive contributions were provided by Ada Core Technologies Inc.      --
+--                                                                          --
+------------------------------------------------------------------------------
+
+with System.Tasking;
+with System.Task_Primitives.Operations;
+with System.Parameters;
+with System.Soft_Links;
+
+with Ada.Unchecked_Conversion;
+
+package body Ada.Task_Termination is
+
+   use type Ada.Task_Identification.Task_Id;
+
+   package STPO renames System.Task_Primitives.Operations;
+   package SSL  renames System.Soft_Links;
+
+   use System.Parameters;
+
+   -----------------------
+   -- Local subprograms --
+   -----------------------
+
+   function To_TT is new Ada.Unchecked_Conversion
+     (System.Tasking.Termination_Handler, Termination_Handler);
+
+   function To_ST is new Ada.Unchecked_Conversion
+     (Termination_Handler, System.Tasking.Termination_Handler);
+
+   function To_Task_Id is new Ada.Unchecked_Conversion
+     (Ada.Task_Identification.Task_Id, System.Tasking.Task_Id);
+
+   -----------------------------------
+   -- Current_Task_Fallback_Handler --
+   -----------------------------------
+
+   function Current_Task_Fallback_Handler return Termination_Handler is
+   begin
+      --  There is no need for explicit protection against race conditions
+      --  for this function because this function can only be executed by
+      --  Self, and the Fall_Back_Handler can only be modified by Self.
+
+      return To_TT (STPO.Self.Common.Fall_Back_Handler);
+   end Current_Task_Fallback_Handler;
+
+   -------------------------------------
+   -- Set_Dependents_Fallback_Handler --
+   -------------------------------------
+
+   procedure Set_Dependents_Fallback_Handler
+     (Handler : Termination_Handler)
+   is
+      Self : constant System.Tasking.Task_Id := STPO.Self;
+
+   begin
+      SSL.Abort_Defer.all;
+
+      if Single_Lock then
+         STPO.Lock_RTS;
+      end if;
+
+      STPO.Write_Lock (Self);
+
+      Self.Common.Fall_Back_Handler := To_ST (Handler);
+
+      STPO.Unlock (Self);
+
+      if Single_Lock then
+         STPO.Unlock_RTS;
+      end if;
+
+      SSL.Abort_Undefer.all;
+   end Set_Dependents_Fallback_Handler;
+
+   --------------------------
+   -- Set_Specific_Handler --
+   --------------------------
+
+   procedure Set_Specific_Handler
+     (T       : Ada.Task_Identification.Task_Id;
+      Handler : Termination_Handler)
+   is
+   begin
+      --  Tasking_Error is raised if the task identified by T has already
+      --  terminated. Program_Error is raised if the value of T is
+      --  Null_Task_Id.
+
+      if T = Ada.Task_Identification.Null_Task_Id then
+         raise Program_Error;
+      elsif Ada.Task_Identification.Is_Terminated (T) then
+         raise Tasking_Error;
+      else
+         declare
+            Target : constant System.Tasking.Task_Id := To_Task_Id (T);
+
+         begin
+            SSL.Abort_Defer.all;
+
+            if Single_Lock then
+               STPO.Lock_RTS;
+            end if;
+
+            STPO.Write_Lock (Target);
+
+            Target.Common.Specific_Handler := To_ST (Handler);
+
+            STPO.Unlock (Target);
+
+            if Single_Lock then
+               STPO.Unlock_RTS;
+            end if;
+
+            SSL.Abort_Undefer.all;
+         end;
+      end if;
+   end Set_Specific_Handler;
+
+   ----------------------
+   -- Specific_Handler --
+   ----------------------
+
+   function Specific_Handler
+     (T : Ada.Task_Identification.Task_Id) return Termination_Handler
+   is
+   begin
+      --  Tasking_Error is raised if the task identified by T has already
+      --  terminated. Program_Error is raised if the value of T is
+      --  Null_Task_Id.
+
+      if T = Ada.Task_Identification.Null_Task_Id then
+         raise Program_Error;
+      elsif Ada.Task_Identification.Is_Terminated (T) then
+         raise Tasking_Error;
+      else
+         declare
+            Target : constant System.Tasking.Task_Id := To_Task_Id (T);
+            TH     : Termination_Handler;
+
+         begin
+            SSL.Abort_Defer.all;
+
+            if Single_Lock then
+               STPO.Lock_RTS;
+            end if;
+
+            STPO.Write_Lock (Target);
+
+            TH := To_TT (Target.Common.Specific_Handler);
+
+            STPO.Unlock (Target);
+
+            if Single_Lock then
+               STPO.Unlock_RTS;
+            end if;
+
+            SSL.Abort_Undefer.all;
+
+            return TH;
+         end;
+      end if;
+   end Specific_Handler;
+
+end Ada.Task_Termination;
diff --git a/gcc/ada/libgnarl/a-taster.ads b/gcc/ada/libgnarl/a-taster.ads
new file mode 100644
index 0000000..21408b5
--- /dev/null
+++ b/gcc/ada/libgnarl/a-taster.ads
@@ -0,0 +1,39 @@
+------------------------------------------------------------------------------
+--                                                                          --
+--                         GNAT RUN-TIME COMPONENTS                         --
+--                                                                          --
+--                 A D A . T A S K _ T E R M I N A T I O N                  --
+--                                                                          --
+--                                 S p e c                                  --
+--                                                                          --
+-- This specification is derived from the Ada Reference Manual for use with --
+-- GNAT.  In accordance with the copyright of that document, you can freely --
+-- copy and modify this specification,  provided that if you redistribute a --
+-- modified version,  any changes that you have made are clearly indicated. --
+--                                                                          --
+------------------------------------------------------------------------------
+
+with Ada.Task_Identification;
+with Ada.Exceptions;
+
+package Ada.Task_Termination is
+   pragma Preelaborate (Task_Termination);
+
+   type Cause_Of_Termination is (Normal, Abnormal, Unhandled_Exception);
+
+   type Termination_Handler is access protected procedure
+     (Cause : Cause_Of_Termination;
+      T     : Ada.Task_Identification.Task_Id;
+      X     : Ada.Exceptions.Exception_Occurrence);
+
+   procedure Set_Dependents_Fallback_Handler
+     (Handler : Termination_Handler);
+   function Current_Task_Fallback_Handler return Termination_Handler;
+
+   procedure Set_Specific_Handler
+     (T       : Ada.Task_Identification.Task_Id;
+      Handler : Termination_Handler);
+   function Specific_Handler
+     (T : Ada.Task_Identification.Task_Id) return Termination_Handler;
+
+end Ada.Task_Termination;