Add e1000 network driver in libe1k

Signed-off-by: Avik Sil <aviksil@linux.vnet.ibm.com>
Signed-off-by: Nikunj A Dadhania <nikunj@linux.vnet.ibm.com>

1 files changed, 95 insertions, 0 deletions

diff --git a/board-qemu/slof/e1k.fs b/board-qemu/slof/e1k.fs
new file mode 100644
index 0000000..7b8e8e6
--- /dev/null
+++ b/board-qemu/slof/e1k.fs
@@ -0,0 +1,95 @@
+\ *****************************************************************************
+\ * Copyright (c) 2013 IBM Corporation
+\ * All rights reserved.
+\ * This program and the accompanying materials
+\ * are made available under the terms of the BSD License
+\ * which accompanies this distribution, and is available at
+\ * http://www.opensource.org/licenses/bsd-license.php
+\ *
+\ * Contributors:
+\ *     IBM Corporation - initial implementation
+\ ****************************************************************************/
+
+\ Handle e1000 device
+
+s" network" device-type
+
+INSTANCE VARIABLE obp-tftp-package
+
+0 VALUE e1k-priv
+0 VALUE open-count
+
+: open  ( -- okay? )
+   open-count 0= IF
+      open IF
+         my-args s" obp-tftp" $open-package obp-tftp-package !
+         e1k-open dup not IF ." e1k-open failed" EXIT THEN
+         drop TO e1k-priv
+         true
+      ELSE
+         false
+      THEN
+   ELSE
+      true
+   THEN
+   open-count 1 + to open-count
+;
+
+
+: close  ( -- )
+    open-count 0> IF
+      open-count 1 - dup to open-count
+      0= IF
+         s" close" obp-tftp-package @ $call-method
+         e1k-priv e1k-close
+         close
+      THEN
+   THEN
+;
+
+: read ( buf len -- actual )
+   dup IF
+      e1k-read
+   ELSE  
+      nip
+   THEN
+;
+
+: write ( buf len -- actual )
+   dup IF
+      e1k-write
+   ELSE
+      nip
+   THEN
+;
+
+: load  ( addr -- len )
+   s" load" obp-tftp-package @ $call-method
+;
+
+: ping  ( -- )
+   s" ping" obp-tftp-package @ $call-method
+;
+
+6 BUFFER: local-mac
+: setup-mac ( -- )
+   pci-mem-enable
+   " vendor-id" get-node get-property IF EXIT THEN
+   decode-int nip nip
+   " device-id" get-node get-property IF EXIT THEN
+   decode-int nip nip
+   " 10 config-l@ translate-my-address 3 not AND" evaluate
+   local-mac e1k-mac-setup IF
+      encode-bytes  " local-mac-address"  property
+   THEN
+;
+setup-mac
+
+: setup-alias  ( -- )
+   s" net" find-alias 0= IF
+      s" net" get-node node>path set-alias
+   ELSE
+      drop
+   THEN
+;
+setup-alias