Import('*')

if env['dri']:

	drienv = env.Clone()

	drienv.Replace(CPPPATH = [
		'#src/mesa/drivers/dri/common',
		'#include',
		'#include/GL/internal',
		'#src/gallium/include',
		'#src/gallium/auxiliary',
		'#src/gallium/drivers',
		'#src/mesa',
		'#src/mesa/main',
		'#src/mesa/glapi',
		'#src/mesa/math',
		'#src/mesa/transform',
		'#src/mesa/shader',
		'#src/mesa/swrast',
		'#src/mesa/swrast_setup',
		'#src/egl/main',
		'#src/egl/drivers/dri',
	])

	drienv.ParseConfig('pkg-config --cflags --libs libdrm')

	COMMON_GALLIUM_SOURCES = [
		'#src/mesa/drivers/dri/common/utils.c',
		'#src/mesa/drivers/dri/common/vblank.c',
		'#src/mesa/drivers/dri/common/dri_util.c',
		'#src/mesa/drivers/dri/common/xmlconfig.c',
	]

	COMMON_BM_SOURCES = [
		'#src/mesa/drivers/dri/common/dri_bufmgr.c',
		'#src/mesa/drivers/dri/common/dri_drmpool.c',
	]

	Export([
		'drienv',
		'COMMON_GALLIUM_SOURCES',
		'COMMON_BM_SOURCES',
	])

	# TODO: Installation
	#install: $(LIBNAME)
	#	$(INSTALL) -d $(DRI_DRIVER_INSTALL_DIR)
	#	$(INSTALL) -m 755 $(LIBNAME) $(DRI_DRIVER_INSTALL_DIR)

	if 'vmware' in env['winsys']:
		SConscript([
			'vmware/SConscript',
		])

	if 'intel' in env['winsys']:
		SConscript([
			'intel/SConscript',
		])

	if 'radeon' in env['winsys']:
		SConscript([
			'radeon/SConscript',
		])
