# Common Tasks

This chapter describes standard tasks such as adding new software packages, extending or customizing images or porting the Yocto Project to new hardware (adding a new machine). The chapter also describes ways to modify package source code, combine multiple versions of library files into a single image, and handle a package name alias. Finally, the chapter contains advice about how to make changes to the Yocto Project to achieve the best results.

## Understanding and Creating Layers

The Yocto Project build system supports organizing metadata into multiple layers. Layers allow you to isolate different types of customizations from each other. You might find it tempting to keep everything in one layer when working on a single project. However, the more modular you organize your metadata, the easier it is to cope with future changes.

To illustrate how layers are used to keep things modular, consider machine customizations. These types of customizations typically reside in a BSP Layer. Furthermore, the machine customizations should be isolated from recipes and metadata that support a new GUI environment, for example. This situation gives you a couple a layers: one for the machine configurations, and one for the GUI environment. It is important to understand, however, that the BSP layer can still make machine-specific additions to recipes within the GUI environment layer without polluting the GUI layer itself with those machine-specific changes. You can accomplish this through a recipe that is a BitBake append (`.bbappend`) file, which is described later in this section.

### Yocto Project Layers

The Yocto Project contains several layers right out of the box. You can easily identify a layer in the Yocto Project by the name of its folder. Folders that are layers begin with the string `meta`. For example, when you set up the Yocto Project Files structure, you will see several layers: `meta`, `meta-demoapps`, `meta-skeleton`, and `meta-yocto`. Each of these folders is a layer.

Furthermore, if you set up a local copy of the `meta-intel` Git repository and then explore that folder, you will discover many BSP layers within the `meta-intel` layer. For more information on BSP layers, see the "BSP Layers" section in the Yocto Project Board Support Package (BSP) Developer's Guide.

### Creating Your Own Layer

It is very easy to create your own layer to use with the Yocto Project. Follow these general steps to create your layer:

1. Check Existing Layers: Before creating a new layer, you should be sure someone has not already created a layer containing the metadata you need. You can see the `LayerIndex` for a list of layers from the OpenEmbedded community that can be used in the Yocto Project.

2. Create a Directory: Create the directory for your layer. Traditionally, prepend the name of the folder with the string `meta`. For example:

            meta-mylayer
            meta-GUI_xyz
            meta-mymachine

3. Create a Layer Configuration File: Inside your new layer folder, you need to create a `conf/layer.conf` file. It is easiest to take an existing layer configuration file and copy that to your layer's `conf` directory and then modify the file as needed.

   The `meta-yocto/conf/layer.conf` file demonstrates the required syntax:

            # We have a conf and classes directory, add to BBPATH
            BBPATH := "${LAYERDIR}:${BBPATH}"

            # We have a packages directory, add to BBFILES
            BBFILES := "${BBFILES} ${LAYERDIR}/recipes-*/*/*.bb \
                        ${LAYERDIR}/recipes-*/*/*.bbappend"

            BBFILE_COLLECTIONS += "yocto"
            BBFILE_PATTERN_yocto := "^${LAYERDIR}/"
            BBFILE_PRIORITY_yocto = "5"

   In the previous example, the recipes for the layers are added to `BBFILES`. The `BBFILE_COLLECTIONS` variable is then appended with the layer name. The `BBFILE_PATTERN` variable is set to a regular expression and is used to match files from `BBFILES` into a particular layer. In this case, immediate expansion of `LAYERDIR` sets `BBFILE_PATTERN` to the layer's path. The `BBFILE_PRIORITY` variable then assigns a priority to the layer. Applying priorities is useful in situations where the same package might appear in multiple layers and allows you to choose what layer should take precedence.

   Note the use of the `LAYERDIR` variable with the immediate expansion operator. The `LAYERDIR` variable expands to the directory of the current layer and requires the immediate expansion operator so that BitBake does not wait to expand the variable when it's parsing a different directory.

   Through the use of the `BBPATH` variable, BitBake locates `.bbclass` files, configuration files, and files that are included with `include` and `require` statements. For these cases, BitBake uses the first file with the matching name found in `BBPATH`. This is similar to the way the `PATH` variable is used for binaries. We recommend, therefore, that you use unique `.bbclass` and configuration file names in your custom layer.

4. Add Content: Depending on the type of layer, add the content. If the layer adds support for a machine, add the machine configuration in a `conf/machine/` file within the layer. If the layer adds distro policy, add the distro configuration in a `conf/distro/` file with the layer. If the layer introduces new recipes, put the recipes you need in `recipes-*` subdirectories within the layer.

To create layers that are easier to maintain, you should consider the following:

- Avoid "overlaying" entire recipes from other layers in your configuration. In other words, don't copy an entire recipe into your layer and then modify it. Use `.bbappend` files to override the parts of the recipe you need to modify.

- Avoid duplicating include files. Use `.bbappend` files for each recipe that uses an include file. Or, if you are introducing a new recipe that requires the included file, use the path relative to the original layer directory to refer to the file. For example, use `require recipes-core/somepackage/somefile.inc` instead of `require somefile.inc`. If you're finding you have to overlay the include file, it could indicate a deficiency in the include file in the layer to which it originally belongs. If this is the case, you need to address that deficiency instead of overlaying the include file. For example, consider how Qt 4 database support plugins are configured. The Yocto Project does not have MySQL or PostgreSQL, however OpenEmbedded's layer `meta-oe` does. Consequently, `meta-oe` uses `.bbappend` files to modify the `QT_SQL_DRIVER_FLAGS` variable to enable the appropriate plugins. This variable was added to the `qt4.inc` include file in The Yocto Project specifically to allow the `meta-oe` layer to be able to control which plugins are built.

We also recommend the following:

- Store custom layers in a Git repository that uses the `meta-<layer_name>` format.

- Clone the repository alongside other `meta` directories in Yocto Project Files.

Following these recommendations keeps your Yocto Project files area and its configuration entirely inside the Yocto Project's core base.

### Enabling Your Layer

Before the Yocto Project build system can use your new layer, you need to enable it. To enable your layer, simply add your layer's path to the `BBLAYERS` variable in your `conf/bblayers.conf` file, which is found in the Yocto Project Build Directory. The following example shows how to enable a layer named `meta-mylayer`:

         LCONF_VERSION = "1"

         BBFILES ?= ""
         BBLAYERS = " \
           /path/to/poky/meta \
           /path/to/poky/meta-yocto \
           /path/to/poky/meta-mylayer \
           "

BitBake parses each `conf/layer.conf` file as specified in the `BBLAYERS` variable within the `conf/bblayers.conf` file. During the processing of each `conf/layer.conf` file, BitBake adds the recipes, classes and configurations contained within the particular layer to the Yocto Project.

### Using .bbappend Files

Recipes used to append metadata to other recipes are called BitBake append files. BitBake append files use the `.bbappend` file type suffix, while underlying recipes to which metadata is being appended use the `.bb` file type suffix.

A `.bbappend` file allows your layer to make additions or changes to the content of another layer's recipe without having to copy the other recipe into your layer. Your `.bbappend` file resides in your layer, while the underlying `.bb` recipe file to which you are appending metadata resides in a different layer.

Append files files must have the same name as the underlying recipe. For example, the append file `someapp_&DISTRO;.bbappend` must apply to `someapp_&DISTRO;.bb`. This means the original recipe and append file names are version number specific. If the underlying recipe is renamed to update to a newer version, the corresponding `.bbappend` file must be renamed as well. During the build process, BitBake displays an error on starting if it detects a `.bbappend` file that does not have an underlying recipe with a matching name.

Being able to append information to an existing recipe not only avoids duplication, but also automatically applies recipe changes in a different layer to your layer. If you were copying recipes, you would have to manually merge changes as they occur.

As an example, consider the main formfactor recipe and a corresponding formfactor append file both from the Yocto Project Files. Here is the main formfactor recipe, which is named `formfactor_0.0.bb` and located in the meta layer at `meta/recipes-bsp/formfactor`:

         DESCRIPTION = "Device formfactor information"
         SECTION = "base"
         LICENSE = "MIT"
         LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
                             file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
         PR = "r20"

         SRC_URI = "file://config file://machconfig"
         S = "${WORKDIR}"

         PACKAGE_ARCH = "${MACHINE_ARCH}"
         INHIBIT_DEFAULT_DEPS = "1"

         do_install() {
         	# Only install file if it has a contents
                 install -d ${D}${sysconfdir}/formfactor/
                 install -m 0644 ${S}/config ${D}${sysconfdir}/formfactor/
         	if [ -s "${S}/machconfig" ]; then
         	        install -m 0644 ${S}/machconfig ${D}${sysconfdir}/formfactor/
         	fi
         }

Here is the append file, which is named `formfactor_0.0.bbappend` and is from the Crown Bay BSP Layer named `meta-intel/meta-crownbay`. The file is in `recipes-bsp/formfactor`:

         FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"

         PRINC = "1"

This example adds or overrides files in `SRC_URI` within a `.bbappend` by extending the path BitBake uses to search for files. The most reliable way to do this is by prepending the `FILESEXTRAPATHS` variable. For example, if you have your files in a directory that is named the same as your package (`PN`), you can add this directory by adding the following to your `.bbappend` file:

         FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"

Using the immediate expansion assignment operator `:=` is important because of the reference to `THISDIR`. The trailing colon character is important as it ensures that items in the list remain colon-separated.

BitBake automatically defines the `THISDIR` variable. You should never set this variable yourself. Using `_prepend` ensures your path will be searched prior to other paths in the final list.

For another example on how to use a `.bbappend` file, see the "Changing `recipes-kernel`" section.

### Prioritizing Your Layer

Each layer is assigned a priority value. Priority values control which layer takes precedence if there are recipe files with the same name in multiple layers. For these cases, the recipe file from the layer with a higher priority number taking precedence. Priority values also affect the order in which multiple `.bbappend` files for the same recipe are applied. You can either specify the priority manually, or allow the build system to calculate it based on the layer's dependencies.

To specify the layer's priority manually, use the `BBFILE_PRIORITY` variable. For example:

         BBFILE_PRIORITY := "1"

It is possible for a recipe with a lower version number `PV` in a layer that has a higher priority to take precedence.

Also, the layer priority does not currently affect the precedence order of `.conf` or `.bbclass` files. Future versions of BitBake might address this.

### Managing Layers

You can use the BitBake layer management tool to provide a view into the structure of recipes across a multi-layer project. Being able to generate output that reports on configured layers with their paths and priorities and on `.bbappend` files and their applicable recipes can help to reveal potential problems.

Use the following form when running the layer management tool.

         $ bitbake-layers <command> [arguments]

The following list describes the available commands:

- `help:` Displays general help or help on a specified command.

- `show-layers:` Show the current configured layers.

- `show-recipes:` Lists available recipes and the layers that provide them.

- `show-overlayed:` Lists overlayed recipes. A recipe is overlayed when a recipe with the same name exists in another layer that has a higher layer priority.

- `show-appends:` Lists `.bbappend` files and the recipe files to which they apply.

- `flatten:` Flattens the layer configuration into a separate output directory. Flattening your layer configuration builds a "flattened" directory that contains the contents of all layers, with any overlayed recipes removed and any `.bbappend` files appended to the corresponding recipes. You might have to perform some manual cleanup of the flattened layer as follows:

  - Non-recipe files (such as patches) are overwritten. The flatten command shows a warning for these files.

  - Anything beyond the normal layer setup has been added to the `layer.conf` file. Only the lowest priority layer's `layer.conf` is used.

  - Overridden and appended items from `.bbappend` files need to be cleaned up. The contents of each `.bbappend` end up in the flattened recipe. However, if there are appended or changed variable values, you need to tidy these up yourself. Consider the following example. Here, the `bitbake-layers` command adds the line `#### bbappended ...` so that you know where the following lines originate:

             ...
             DESCRIPTION = "A useful utility"
             ...
             EXTRA_OECONF = "--enable-something"
             ...

             #### bbappended from meta-anotherlayer ####

             DESCRIPTION = "Customized utility"
             EXTRA_OECONF += "--enable-somethingelse"

    Ideally, you would tidy up these utilities as follows:

             ...
             DESCRIPTION = "Customized utility"
             ...
             EXTRA_OECONF = "--enable-something --enable-somethingelse"
             ...

## Customizing Images

You can customize Yocto Project images to satisfy particular requirements. This section describes several methods and provides guidelines for each.

### Customizing Images Using Custom .bb Files

One way to get additional software into an image is to create a custom image. The following example shows the form for the two lines you need:

         IMAGE_INSTALL = "task-core-x11-base package1 package2"

         inherit core-image

By creating a custom image, a developer has total control over the contents of the image. It is important to use the correct names of packages in the `IMAGE_INSTALL` variable. You must use the OpenEmbedded notation and not the Debian notation for the names (e.g. `eglibc-dev` instead of `libc6-dev`).

The other method for creating a custom image is to base it on an existing image. For example, if you want to create an image based on `core-image-sato` but add the additional package `strace` to the image, copy the `meta/recipes-sato/images/core-image-sato.bb` to a new `.bb` and add the following line to the end of the copy:

         IMAGE_INSTALL += "strace"

### Customizing Images Using Custom Tasks

For complex custom images, the best approach is to create a custom task package that is used to build the image or images. A good example of a tasks package is `meta/recipes-core/tasks/task-core-boot.bb` The `PACKAGES` variable lists the task packages to build along with the complementary `-dbg` and `-dev` packages. For each package added, you can use `RDEPENDS` and `RRECOMMENDS` entries to provide a list of packages the parent task package should contain. Following is an example:

         DESCRIPTION = "My Custom Tasks"

         PACKAGES = "\
             task-custom-apps \
             task-custom-apps-dbg \
             task-custom-apps-dev \
             task-custom-tools \
             task-custom-tools-dbg \
             task-custom-tools-dev \
             "

         RDEPENDS_task-custom-apps = "\
             dropbear \
             portmap \
             psplash"

         RDEPENDS_task-custom-tools = "\
             oprofile \
             oprofileui-server \
             lttng-control \
             lttng-viewer"

         RRECOMMENDS_task-custom-tools = "\
             kernel-module-oprofile"

In the previous example, two task packages are created with their dependencies and their recommended package dependencies listed: `task-custom-apps`, and `task-custom-tools`. To build an image using these task packages, you need to add `task-custom-apps` and/or `task-custom-tools` to `IMAGE_INSTALL`. For other forms of image dependencies see the other areas of this section.

### Customizing Images Using Custom `IMAGE_FEATURES` and `EXTRA_IMAGE_FEATURES`

Ultimately users might want to add extra image features to the set used by Yocto Project with the `IMAGE_FEATURES` variable. To create these features, the best reference is `meta/classes/core-image.bbclass`, which shows how the Yocto Project achieves this. In summary, the file looks at the contents of the `IMAGE_FEATURES` variable and then maps that into a set of tasks or packages. Based on this information the `IMAGE_INSTALL` variable is generated automatically. Users can add extra features by extending the class or creating a custom class for use with specialized image `.bb` files. You can also add more features by configuring the `EXTRA_IMAGE_FEATURES` variable in the `local.conf` file found in the Yocto Project files located in the build directory.

The Yocto Project ships with two SSH servers you can use in your images: Dropbear and OpenSSH. Dropbear is a minimal SSH server appropriate for resource-constrained environments, while OpenSSH is a well-known standard SSH server implementation. By default, the `core-image-sato` image is configured to use Dropbear. The `core-image-basic` and `core-image-lsb` images both include OpenSSH. To change these defaults, edit the `IMAGE_FEATURES` variable so that it sets the image you are working with to include `ssh-server-dropbear` or `ssh-server-openssh`.

### Customizing Images Using `local.conf`

It is possible to customize image contents by using variables from your local configuration in your `conf/local.conf` file. Because it is limited to local use, this method generally only allows you to add packages and is not as flexible as creating your own customized image. When you add packages using local variables this way, you need to realize that these variable changes affect all images at the same time and might not be what you require.

The simplest way to add extra packages to all images is by using the `IMAGE_INSTALL` variable with the `_append` operator:

         IMAGE_INSTALL_append = " strace"

Use of the syntax is important. Specifically, the space between the quote and the package name, which is `strace` in this example. This space is required since the `_append` operator does not add the space.

Furthermore, you must use `_append` instead of the `+=` operator if you want to avoid ordering issues. The reason for this is because doing so unconditionally appends to the variable and avoids ordering problems due to the variable being set in image recipes and `.bbclass` files with operators like `?=`. Using `_append` ensures the operation takes affect.

As shown in its simplest use, `IMAGE_INSTALL_append` affects all images. It is possible to extend the syntax so that the variable applies to a specific image only. Here is an example:

         IMAGE_INSTALL_append_pn-core-image-minimal = " strace"

This example adds `strace` to `core-image-minimal` only.

You can add packages using a similar approach through the `CORE_IMAGE_EXTRA_INSTALL` variable. If you use this variable, only `core-image-*` images are affected.

## Adding a Package

To add a package into the Yocto Project you need to write a recipe for it. Writing a recipe means creating a `.bb` file that sets some variables. For information on variables that are useful for recipes and for information about recipe naming issues, see the "Required" section of the Yocto Project Reference Manual.

Before writing a recipe from scratch, it is often useful to check whether someone else has written one already. OpenEmbedded is a good place to look as it has a wider scope and range of packages. Because the Yocto Project aims to be compatible with OpenEmbedded, most recipes you find there should work in Yocto Project.

For new packages, the simplest way to add a recipe is to base it on a similar pre-existing recipe. The sections that follow provide some examples that show how to add standard types of packages.

### Single .c File Package (Hello World!)

Building an application from a single file that is stored locally (e.g. under `files/`) requires a recipe that has the file listed in the `SRC_URI` variable. Additionally, you need to manually write the `do_compile` and `do_install` tasks. The `S` variable defines the directory containing the source code, which is set to `WORKDIR` in this case - the directory BitBake uses for the build.

         DESCRIPTION = "Simple helloworld application"
         SECTION = "examples"
         LICENSE = "MIT"
         LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
         PR = "r0"

         SRC_URI = "file://helloworld.c"

         S = "${WORKDIR}"

         do_compile() {
         	${CC} helloworld.c -o helloworld
         }

         do_install() {
         	install -d ${D}${bindir}
         	install -m 0755 helloworld ${D}${bindir}
         }

By default, the `helloworld`, `helloworld-dbg`, and `helloworld-dev` packages are built. For information on how to customize the packaging process, see the "Splitting an Application into Multiple Packages" section.

### Autotooled Package

Applications that use Autotools such as `autoconf` and `automake` require a recipe that has a source archive listed in `SRC_URI` and also inherits Autotools, which instructs BitBake to use the `autotools.bbclass` file, which contains the definitions of all the steps needed to build an Autotool-based application. The result of the build is automatically packaged. And, if the application uses NLS for localization, packages with local information are generated (one package per language). Following is one example: (`hello_2.3.bb`)

         DESCRIPTION = "GNU Helloworld application"
         SECTION = "examples"
         LICENSE = "GPLv2+"
         LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
         PR = "r0"

         SRC_URI = "${GNU_MIRROR}/hello/hello-${PV}.tar.gz"

         inherit autotools gettext

The variable `LIC_FILES_CHKSUM` is used to track source license changes as described in the "Track License Changes" section. You can quickly create Autotool-based recipes in a manner similar to the previous example.

### Makefile-Based Package

Applications that use GNU `make` also require a recipe that has the source archive listed in `SRC_URI`. You do not need to add a `do_compile` step since by default BitBake starts the `make` command to compile the application. If you need additional `make` options you should store them in the `EXTRA_OEMAKE` variable. BitBake passes these options into the `make` GNU invocation. Note that a `do_install` task is still required. Otherwise BitBake runs an empty `do_install` task by default.

Some applications might require extra parameters to be passed to the compiler. For example, the application might need an additional header path. You can accomplish this by adding to the `CFLAGS` variable. The following example shows this:

         CFLAGS_prepend = "-I ${S}/include "

In the following example, `mtd-utils` is a makefile-based package:

         DESCRIPTION = "Tools for managing memory technology devices."
         SECTION = "base"
         DEPENDS = "zlib lzo e2fsprogs util-linux"
         HOMEPAGE = "http://www.linux-mtd.infradead.org/"
         LICENSE = "GPLv2+"
         LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
                        file://include/common.h;beginline=1;endline=17;md5=ba05b07912a44ea2bf81ce409380049c"

         SRC_URI = "git://git.infradead.org/mtd-utils.git;protocol=git;tag=995cfe51b0a3cf32f381c140bf72b21bf91cef1b \
    	     	file://add-exclusion-to-mkfs-jffs2-git-2.patch"

         S = "${WORKDIR}/git/"

         PR = "r1"

         EXTRA_OEMAKE = "'CC=${CC}' 'RANLIB=${RANLIB}' 'AR=${AR}' \
            'CFLAGS=${CFLAGS} -I${S}/include -DWITHOUT_XATTR' 'BUILDDIR=${S}'"

         do_install () {
    	     oe_runmake install DESTDIR=${D} SBINDIR=${sbindir} MANDIR=${mandir} \
                INCLUDEDIR=${includedir}
    	     install -d ${D}${includedir}/mtd/
    	     for f in ${S}/include/mtd/*.h; do
    	     	install -m 0644 $f ${D}${includedir}/mtd/
    	     done
         }

         PARALLEL_MAKE = ""

         BBCLASSEXTEND = "native"

If your sources are available as a tarball instead of a Git repository, you will need to provide the URL to the tarball as well as an `md5` or `sha256` sum of the download. Here is an example:

         SRC_URI="ftp://ftp.infradead.org/pub/mtd-utils/mtd-utils-1.4.9.tar.bz2"
         SRC_URI[md5sum]="82b8e714b90674896570968f70ca778b"

You can generate the `md5` or `sha256` sums by using the `md5sum` or `sha256sum` commands with the target file as the only argument. Here is an example:

         $ md5sum mtd-utils-1.4.9.tar.bz2
         82b8e714b90674896570968f70ca778b mtd-utils-1.4.9.tar.bz2

### Splitting an Application into Multiple Packages

You can use the variables `PACKAGES` and `FILES` to split an application into multiple packages.

Following is an example that uses the `libXpm` recipe. By default, this recipe generates a single package that contains the library along with a few binaries. You can modify the recipe to split the binaries into separate packages:

         require xorg-lib-common.inc

         DESCRIPTION = "X11 Pixmap library"
         LICENSE = "X-BSD"
         LIC_FILES_CHKSUM = "file://COPYING;md5=3e07763d16963c3af12db271a31abaa5"
         DEPENDS += "libxext libsm libxt"
         PR = "r3"
         PE = "1"

         XORG_PN = "libXpm"

         PACKAGES =+ "sxpm cxpm"
         FILES_cxpm = "${bindir}/cxpm"
         FILES_sxpm = "${bindir}/sxpm"

In the previous example, we want to ship the `sxpm` and `cxpm` binaries in separate packages. Since `bindir` would be packaged into the main `PN` package by default, we prepend the `PACKAGES` variable so additional package names are added to the start of list. This results in the extra `FILES_*` variables then containing information that define which files and directories go into which packages. Files included by earlier packages are skipped by latter packages. Thus, the main `PN` package does not include the above listed files.

### Including Static Library Files

If you are building a library and the library offers static linking, you can control which static library files (`*.a` files) get included in the built library.

The `PACKAGES` and `FILES_*` variables in the `meta/conf/bitbake.conf` configuration file define how files installed by the `do_install` task are packaged. By default, the `PACKAGES` variable contains `${PN}-staticdev`, which includes all static library files.

Previously released versions of the Yocto Project defined the static library files through `${PN}-dev`.

Following, is part of the BitBake configuration file. You can see where the static library files are defined:

         PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-staticdev ${PN}-locale"
         PACKAGES_DYNAMIC = "${PN}-locale-*"
         FILES = ""

         FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
                     ${sysconfdir} ${sharedstatedir} ${localstatedir} \
                     ${base_bindir}/* ${base_sbindir}/* \
                     ${base_libdir}/*${SOLIBS} \
                     ${datadir}/${BPN} ${libdir}/${BPN}/* \
                     ${datadir}/pixmaps ${datadir}/applications \
                     ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
                     ${libdir}/bonobo/servers"

         FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
                     ${datadir}/gnome/help"
         SECTION_${PN}-doc = "doc"

         FILES_${PN}-dev = "${includedir} ${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la \
                         ${libdir}/*.o ${libdir}/pkgconfig ${datadir}/pkgconfig \
                         ${datadir}/aclocal ${base_libdir}/*.o"
         SECTION_${PN}-dev = "devel"
         ALLOW_EMPTY_${PN}-dev = "1"
         RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPKGV})"

         FILES_${PN}-staticdev = "${libdir}/*.a ${base_libdir}/*.a"
         SECTION_${PN}-staticdev = "devel"
         RDEPENDS_${PN}-staticdev = "${PN}-dev (= ${EXTENDPKGV})"

### Post Install Scripts

To add a post-installation script to a package, add a `pkg_postinst_PACKAGENAME()` function to the `.bb` file and use `PACKAGENAME` as the name of the package you want to attach to the `postinst` script. Normally `PN` can be used, which automatically expands to `PACKAGENAME`. A post-installation function has the following structure:

         pkg_postinst_PACKAGENAME () {
         #!/bin/sh -e
         # Commands to carry out
         }

The script defined in the post-installation function is called when the root filesystem is created. If the script succeeds, the package is marked as installed. If the script fails, the package is marked as unpacked and the script is executed when the image boots again.

Sometimes it is necessary for the execution of a post-installation script to be delayed until the first boot. For example, the script might need to be executed on the device itself. To delay script execution until boot time, use the following structure in the post-installation script:

         pkg_postinst_PACKAGENAME () {
         #!/bin/sh -e
         if [ x"$D" = "x" ]; then
              # Actions to carry out on the device go here
         else
              exit 1
         fi
         }

The previous example delays execution until the image boots again because the `D` variable points to the directory containing the image when the root filesystem is created at build time but is unset when executed on the first boot.

## Porting the Yocto Project to a New Machine

Adding a new machine to the Yocto Project is a straightforward process. This section provides information that gives you an idea of the changes you must make. The information covers adding machines similar to those the Yocto Project already supports. Although well within the capabilities of the Yocto Project, adding a totally new architecture might require changes to `gcc/eglibc` and to the site information, which is beyond the scope of this manual.

For a complete example that shows how to add a new machine to the Yocto Project, see the "BSP Development Example" in Appendix A.

### Adding the Machine Configuration File

To add a machine configuration you need to add a `.conf` file with details of the device being added to the `conf/machine/` file. The name of the file determines the name the Yocto Project uses to reference the new machine.

The most important variables to set in this file are as follows:

- `TARGET_ARCH` (e.g. "arm")

- `PREFERRED_PROVIDER`_virtual/kernel (see below)

- `MACHINE_FEATURES` (e.g. "apm screen wifi")

You might also need these variables:

- `SERIAL_CONSOLE` (e.g. "115200 ttyS0")

- `KERNEL_IMAGETYPE` (e.g. "zImage")

- `IMAGE_FSTYPES` (e.g. "tar.gz jffs2")

You can find full details on these variables in the reference section. You can leverage many existing machine `.conf` files from `meta/conf/machine/`.

### Adding a Kernel for the Machine

The Yocto Project needs to be able to build a kernel for the machine. You need to either create a new kernel recipe for this machine, or extend an existing recipe. You can find several kernel examples in the Yocto Project file's `meta/recipes-kernel/linux` directory that you can use as references.

If you are creating a new recipe, normal recipe-writing rules apply for setting up a `SRC_URI`. Thus, you need to specify any necessary patches and set `S` to point at the source code. You need to create a `configure` task that configures the unpacked kernel with a defconfig. You can do this by using a `make defconfig` command or, more commonly, by copying in a suitable `defconfig` file and and then running `make oldconfig`. By making use of `inherit kernel` and potentially some of the `linux-*.inc` files, most other functionality is centralized and the the defaults of the class normally work well.

If you are extending an existing kernel, it is usually a matter of adding a suitable defconfig file. The file needs to be added into a location similar to defconfig files used for other machines in a given kernel. A possible way to do this is by listing the file in the `SRC_URI` and adding the machine to the expression in `COMPATIBLE_MACHINE`:

         COMPATIBLE_MACHINE = '(qemux86|qemumips)'

### Adding a Formfactor Configuration File

A formfactor configuration file provides information about the target hardware for which the Yocto Project is building and information that the Yocto Project cannot obtain from other sources such as the kernel. Some examples of information contained in a formfactor configuration file include framebuffer orientation, whether or not the system has a keyboard, the positioning of the keyboard in relation to the screen, and the screen resolution.

The Yocto Project uses reasonable defaults in most cases, but if customization is necessary you need to create a `machconfig` file in the Yocto Project file's `meta/recipes-bsp/formfactor/files` directory. This directory contains directories for specific machines such as `qemuarm` and `qemux86`. For information about the settings available and the defaults, see the `meta/recipes-bsp/formfactor/files/config` file found in the same area. Following is an example for qemuarm:

         HAVE_TOUCHSCREEN=1
         HAVE_KEYBOARD=1

         DISPLAY_CAN_ROTATE=0
         DISPLAY_ORIENTATION=0
         #DISPLAY_WIDTH_PIXELS=640
         #DISPLAY_HEIGHT_PIXELS=480
         #DISPLAY_BPP=16
         DISPLAY_DPI=150
         DISPLAY_SUBPIXEL_ORDER=vrgb

## Modifying Temporary Source Code

Although the Yocto Project is typically used to build software, you might find it helpful during development to modify the temporary source code used by recipes to build packages. For example, suppose you are developing a patch and you need to experiment a bit to figure out your solution. After you have initially built the package, you can iteratively tweak the source code, which is located in the Yocto Project's Build Directory, and then you can force a re-compile and quickly test your altered code. Once you settle on a solution, you can then preserve your changes in the form of patches. You can accomplish these steps all within either a Quilt or Git workflow.

### Finding the Temporary Source Code

During a build, the unpacked temporary source code used by recipes to build packages is available in the Yocto Project Build Directory as defined by the `S` variable. Below is the default value for the `S` variable as defined in the `meta/conf/bitbake.conf` configuration file in the Yocto Project Files:

         S = ${WORKDIR}/${BP}

You should be aware that many recipes override the `S` variable. For example, recipes that fetch their source from Git usually set `S` to `${WORKDIR}/git`.

`BP` represents the "Base Package", which is the base package name and the package version:

         BP = ${BPN}-${PV}

The path to the work directory for the recipe (`WORKDIR`) depends on the package name and the architecture of the target device. For example, here is the work directory for packages whose targets are not device-dependent:

         ${TMPDIR}/work/${PACKAGE_ARCH}-poky-${TARGET_OS}/${PN}-${PV}-${PR}

Let's look at an example without variables. Assuming a Yocto Project Files top-level directory named `poky` and a default Yocto Project Build Directory of `poky/build`, the following is the work directory for the `acl` package:

         ~/poky/build/tmp/work/i586-poky-linux/acl-2.2.51-r3

If your package is dependent on the target device, the work directory varies slightly:

         ${TMPDIR}/work/${MACHINE}-poky-${TARGET_OS}/${PN}-${PV}-${PR}

Again, assuming a Yocto Project Files top-level directory named `poky` and a default Yocto Project Build Directory of `poky/build`, the following is the work directory for the `acl` package that is being built for a MIPS-based device:

         ~/poky/build/tmp/work/mips-poky-linux/acl-2.2.51-r2

To better understand how the Yocto Project build system resolves directories during the build process, see the glossary entries for the `WORKDIR`, `TMPDIR`, `TOPDIR`, `PACKAGE_ARCH`, `TARGET_OS`, `PN`, `PV`, and `PR` variables in the Yocto Project Reference Manual.

Now that you know where to locate the directory that has the temporary source code, you can use a Quilt or Git workflow to make your edits, test the changes, and preserve the changes in the form of patches.

### Using a Quilt Workflow

Quilt is a powerful tool that allows you to capture source code changes without having a clean source tree. This section outlines the typical workflow you can use to modify temporary source code, test changes, and then preserve the changes in the form of a patch all using Quilt.

Follow these general steps:

1. Find the Source Code: The temporary source code used by the Yocto Project build system is kept in the Yocto Project Build Directory. See the "Finding the Temporary Source Code" section to learn how to locate the directory that has the temporary source code for a particular package.

2. Change Your Working Directory: You need to be in the directory that has the temporary source code. That directory is defined by the S variable.

3. Create a New Patch: Before modifying source code, you need to create a new patch. To create a new patch file, use `quilt new` as below:

            $ quilt new my_changes.patch

4. Notify Quilt and Add Files: After creating the patch, you need to notify Quilt about the files you will be changing. Add the files you will be modifying into the patch you just created:

            $ quilt add file1.c file2.c file3.c

5. Edit the Files: Make the changes to the temporary source code.

6. Test Your Changes: Once you have modified the source code, the easiest way to test your changes is by calling the `compile` task as shown in the following example:

            $ bitbake -c compile -f <name_of_package>

   The `-f` or `--force` option forces re-execution of the specified task. If you find problems with your code, you can just keep editing and re-testing iteratively until things work as expected.

   All the modifications you make to the temporary source code disappear once you `-c clean` or `-c cleanall` with BitBake for the package. Modifications will also disappear if you use the `rm_work` feature as described in the "Building an Image" section of the Yocto Project Quick Start.

7. Generate the Patch: Once your changes work as expected, you need to use Quilt to generate the final patch that contains all your modifications.

            $ quilt refresh

   At this point the `my_changes.patch` file has all your edits made to the `file1.c`, `file2.c`, and `file3.c` files.

   You can find the resulting patch file in the `patches/` subdirectory of the source (`S`) directory.

8. Copy the Patch File: For simplicity, copy the patch file into a directory named `files`, which you can create in the same directory as the recipe. Placing the patch here guarantees that the Yocto Project build system will find the patch. Next, add the patch into the `SRC_URI` of the recipe. Here is an example:

            SRC_URI += "file://my_changes.patch"

9. Increment the Package Revision Number: Finally, don't forget to 'bump' the `PR` value in the same recipe since the resulting packages have changed.

### Using a Git Workflow

Git is an even more powerful tool that allows you to capture source code changes without having a clean source tree. This section outlines the typical workflow you can use to modify temporary source code, test changes, and then preserve the changes in the form of a patch all using Git. For general information on Git as it is used in the Yocto Project, see the "Git" section.

This workflow uses Git only for its ability to manage local changes to the source code and produce patches independent of any version control used on the Yocto Project Files.

Follow these general steps:

1. Find the Source Code: The temporary source code used by the Yocto Project build system is kept in the Yocto Project Build Directory. See the "Finding the Temporary Source Code" section to learn how to locate the directory that has the temporary source code for a particular package.

2. Change Your Working Directory: You need to be in the directory that has the temporary source code. That directory is defined by the S variable.

3. Initialize a Git Repository: Use the `git init` command to initialize a new local repository that is based on the work directory:

            $ git init

4. Stage all the files: Use the `git add *` command to stage all the files in the source code directory so that they can be committed:

            $ git add *

5. Commit the Source Files: Use the `git commit` command to initially commit all the files in the work directory:

            $ git commit

   At this point, your Git repository is aware of all the source code files. Any edits you now make to files will be tracked by Git.

6. Edit the Files: Make the changes to the temporary source code.

7. Test Your Changes: Once you have modified the source code, the easiest way to test your changes is by calling the `compile` task as shown in the following example:

            $ bitbake -c compile -f <name_of_package>

   The `-f` or `--force` option forces re-execution of the specified task. If you find problems with your code, you can just keep editing and re-testing iteratively until things work as expected.

   All the modifications you make to the temporary source code disappear once you `-c clean` or `-c cleanall` with BitBake for the package. Modifications will also disappear if you use the `rm_work` feature as described in the "Building an Image" section of the Yocto Project Quick Start.

8. See the List of Files You Changed: Use the `git status` command to see what files you have actually edited. The ability to have Git track the files you have changed is an advantage that this workflow has over the Quilt workflow. Here is the Git command to list your changed files:

            $ git status

9. Stage the Modified Files: Use the `git add` command to stage the changed files so they can be committed as follows:

            $ git add file1.c file2.c file3.c

10. Commit the Staged Files and View Your Changes: Use the `git commit` command to commit the changes to the local repository. Once you have committed the files, you can use the `git log` command to see your changes:

             $ git commit
             $ git log

11. Generate the Patch: Once the changes are committed, use the `git format-patch` command to generate a patch file:

             $ git format-patch HEAD~1

    The `HEAD~1` part of the command causes Git to generate the patch file for the most recent commit.

    At this point, the patch file has all your edits made to the `file1.c`, `file2.c`, and `file3.c` files. You can find the resulting patch file in the current directory. The patch file ends with `.patch`.

12. Copy the Patch File: For simplicity, copy the patch file into a directory named `files`, which you can create in the same directory as the recipe. Placing the patch here guarantees that the Yocto Project build system will find the patch. Next, add the patch into the `SRC_URI` of the recipe. Here is an example:

             SRC_URI += "file://my_changes.patch"

13. Increment the Package Revision Number: Finally, don't forget to 'bump' the `PR` value in the same recipe since the resulting packages have changed.

## Combining Multiple Versions of Library Files into One Image

The build system offers the ability to build libraries with different target optimizations or architecture formats and combine these together into one system image. You can link different binaries in the image against the different libraries as needed for specific use cases. This feature is called "Multilib."

An example would be where you have most of a system compiled in 32-bit mode using 32-bit libraries, but you have something large, like a database engine, that needs to be a 64-bit application and use 64-bit libraries. Multilib allows you to get the best of both 32-bit and 64-bit libraries.

While the Multilib feature is most commonly used for 32 and 64-bit differences, the approach the build system uses facilitates different target optimizations. You could compile some binaries to use one set of libraries and other binaries to use other different sets of libraries. The libraries could differ in architecture, compiler options, or other optimizations.

This section overviews the Multilib process only. For more details on how to implement Multilib, see the Multilib wiki page.

### Preparing to use Multilib

User-specific requirements drive the Multilib feature, Consequently, there is no one "out-of-the-box" configuration that likely exists to meet your needs.

In order to enable Multilib, you first need to ensure your recipe is extended to support multiple libraries. Many standard recipes are already extended and support multiple libraries. You can check in the `meta/conf/multilib.conf` configuration file in the Yocto Project files directory to see how this is done using the `BBCLASSEXTEND` variable. Eventually, all recipes will be covered and this list will be unneeded.

For the most part, the Multilib class extension works automatically to extend the package name from `${PN}` to `${MLPREFIX}${PN}`, where `MLPREFIX` is the particular multilib (e.g. "lib32-" or "lib64-"). Standard variables such as `DEPENDS`, `RDEPENDS`, `RPROVIDES`, `RRECOMMENDS`, `PACKAGES`, and `PACKAGES_DYNAMIC` are automatically extended by the system. If you are extending any manual code in the recipe, you can use the `${MLPREFIX}` variable to ensure those names are extended correctly. This automatic extension code resides in `multilib.bbclass`.

### Using Multilib

After you have set up the recipes, you need to define the actual combination of multiple libraries you want to build. You accomplish this through your `local.conf` configuration file in the Yocto Project Build Directory. An example configuration would be as follows:

         MACHINE = "qemux86-64"
         require conf/multilib.conf
         MULTILIBS = "multilib:lib32"
         DEFAULTTUNE_virtclass-multilib-lib32 = "x86"
         IMAGE_INSTALL = "lib32-connman"

This example enables an additional library named `lib32` alongside the normal target packages. When combining these "lib32" alternatives, the example uses "x86" for tuning. For information on this particular tuning, see `meta/conf/machine/include/ia32/arch-ia32.inc`.

The example then includes `lib32-connman` in all the images, which illustrates one method of including a multiple library dependency. You can use a normal image build to include this dependency, for example:

         $ bitbake core-image-sato

You can also build Multilib packages specifically with a command like this:

         $  bitbake lib32-connman

### Additional Implementation Details

Different packaging systems have different levels of native Multilib support. For the RPM Package Management System, the following implementation details exist:

- A unique architecture is defined for the Multilib packages, along with creating a unique deploy folder under `tmp/deploy/rpm` in the Yocto Project Build Directory. For example, consider `lib32` in a `qemux86-64` image. The possible architectures in the system are "all", "qemux86_64", "lib32_qemux86_64", and "lib32_x86".

- The `${MLPREFIX}` variable is stripped from `${PN}` during RPM packaging. The naming for a normal RPM package and a Multilib RPM package in a `qemux86-64` system resolves to something similar to `bash-4.1-r2.x86_64.rpm` and `bash-4.1.r2.lib32_x86.rpm`, respectively.

- When installing a Multilib image, the RPM backend first installs the base image and then installs the Multilib libraries.

- The build system relies on RPM to resolve the identical files in the two (or more) Multilib packages.

For the IPK Package Management System, the following implementation details exist:

- The `${MLPREFIX}` is not stripped from `${PN}` during IPK packaging. The naming for a normal RPM package and a Multilib IPK package in a `qemux86-64` system resolves to something like `bash_4.1-r2.x86_64.ipk` and `lib32-bash_4.1-rw_x86.ipk`, respectively.

- The IPK deploy folder is not modified with `${MLPREFIX}` because packages with and without the Multilib feature can exist in the same folder due to the `${PN}` differences.

- IPK defines a sanity check for Multilib installation using certain rules for file comparison, overridden, etc.

## Configuring the Kernel

Configuring the Linux Yocto kernel consists of making sure the `.config` file has all the right information in it for the image you are building. You can use the `menuconfig` tool and configuration fragments to make sure your `.config` file is just how you need it. This section describes how to use `menuconfig`, create and use configuration fragments, and how to interactively tweak your `.config` file to create the leanest kernel configuration file possible.

For concepts on kernel configuration, see the "Kernel Configuration" section in the Yocto Project Kernel Architecture and Use Manual.

### Using `menuconfig`

The easiest way to define kernel configurations is to set them through the `menuconfig` tool. For general information on `menuconfig`, see .

To use the `menuconfig` tool in the Yocto Project development environment, you must build the tool using BitBake. The following commands build and invoke `menuconfig` assuming the Yocto Project files top-level directory is `~/poky`:

         $ cd ~/poky
         $ source oe-init-build-env
         $ bitbake linux-yocto -c menuconfig

Once `menuconfig` comes up, its standard interface allows you to examine and configure all the kernel configuration parameters. Once you have made your changes, simply exit the tool and save your changes to create an updated version of the `.config` configuration file.

For an example that shows how to change the `SMP_CONFIG` parameter using `menuconfig`, see the "Changing the `CONFIG_SMP` Configuration Using `menuconfig`" section.

### Creating Config Fragments

Configuration fragments are simply kernel options that appear in a file. Syntactically, the configuration statement is identical to what would appear in the `.config`. For example, issuing the following from the shell would create a config fragment file named `my_smp.cfg` that enables multi-processor support within the kernel:

         $ echo "CONFIG_SMP=y" >> my_smp.cfg

Where do you put your configuration files? You can place these configuration files in the same area pointed to by `SRC_URI`. The Yocto Project build process will pick up the configuration and add it to the kernel's configuration. For example, assume you add the following to your `linux-yocto_3.0.bbappend` file:

         file://my_smp.cfg

You would put the config fragment file `my_smp.cfg` in a sub-directory with the same root name (`linux-yocto`) beneath the directory that contains your `linux-yocto_3.0.bbappend` file and the build system will pick up and apply the fragment.

### Fine-tuning the Kernel Configuration File

You can make sure the `.config` is as lean or efficient as possible by reading the output of the kernel configuration fragment audit, noting any issues, making changes to correct the issues, and then repeating.

As part of the Linux Yocto kernel build process, the `kernel_configcheck` task runs. This task validates the kernel configuration by checking the final `.config` file against the input files. During the check, the task produces warning messages for the following issues:

- Requested options that did not make the final `.config` file.

- Configuration items that appear twice in the same configuration fragment.

- Configuration items tagged as 'required' were overridden.

- A board overrides a non-board specific option.

- Listed options not valid for the kernel being processed. In other words, the option does not appear anywhere.

The `kernel_configcheck` task can also optionally report if an option is overridden during processing.

For each output warning, a message points to the file that contains a list of the options and a pointer to the config fragment that defines them. Collectively, the files are the key to streamlining the configuration.

To streamline the configuration, do the following:

1. Start with a full configuration that you know works - it builds and boots successfully. This configuration file will be your baseline.

2. Separately run the `configme` and `kernel_configcheck` tasks.

3. Take the resulting list of files from the `kernel_configcheck` task warnings and do the following:

   - Drop values that are redefined in the fragment but do not change the final `.config` file.

   - Analyze and potentially drop values from the `.config` file that override required configurations.

   - Analyze and potentially remove non-board specific options.

   - Remove repeated and invalid options.

4. After you have worked through the output of the kernel configuration audit, you can re-run the `configme` and `kernel_configcheck` tasks to see the results of your changes. If you have more issues, you can deal with them as described in the previous step.

Iteratively working through steps two through four eventually yields a minimal, streamlined configuration file. Once you have the best `.config`, you can build the Linux Yocto kernel.

## Updating Existing Images

Often, rather than re-flashing a new image, you might wish to install updated packages into an existing running system. You can do this by first sharing the `tmp/deploy/ipk/` directory through a web server and then by changing `/etc/opkg/base-feeds.conf` to point at the shared server. Following is an example:

         $ src/gz all http://www.mysite.com/somedir/deploy/ipk/all
         $ src/gz armv7a http://www.mysite.com/somedir/deploy/ipk/armv7a
         $ src/gz beagleboard http://www.mysite.com/somedir/deploy/ipk/beagleboard

## Incrementing a Package Revision Number

If a committed change results in changing the package output, then the value of the `PR` variable needs to be increased (or "bumped") as part of that commit. This means that for new recipes you must be sure to add the `PR` variable and set its initial value equal to "r0". Failing to define `PR` makes it easy to miss when you bump a package. Note that you can only use integer values following the "r" in the `PR` variable.

If you are sharing a common `.inc` file with multiple recipes, you can also use the `INC_PR` variable to ensure that the recipes sharing the `.inc` file are rebuilt when the `.inc` file itself is changed. The `.inc` file must set `INC_PR` (initially to "r0"), and all recipes referring to it should set `PR` to "$(INC_PR).0" initially, incrementing the last number when the recipe is changed. If the `.inc` file is changed then its `INC_PR` should be incremented.

When upgrading the version of a package, assuming the `PV` changes, the `PR` variable should be reset to "r0" (or "$(INC_PR).0" if you are using `INC_PR`).

Usually, version increases occur only to packages. However, if for some reason `PV` changes but does not increase, you can increase the `PE` variable (Package Epoch). The `PE` variable defaults to "0".

Version numbering strives to follow the Debian Version Field Policy Guidelines. These guidelines define how versions are compared and what "increasing" a version means.

There are two reasons for following the previously mentioned guidelines. First, to ensure that when a developer updates and rebuilds, they get all the changes to the repository and do not have to remember to rebuild any sections. Second, to ensure that target users are able to upgrade their devices using package manager commands such as `opkg upgrade` (or similar commands for dpkg/apt or rpm-based systems).

The goal is to ensure the Yocto Project has packages that can be upgraded in all cases.

## Handling a Package Name Alias

Sometimes a package name you are using might exist under an alias or as a similarly named package in a different distribution. The Yocto Project implements a `distro_check` task that automatically connects to major distributions and checks for these situations. If the package exists under a different name in a different distribution, you get a `distro_check` mismatch. You can resolve this problem by defining a per-distro recipe name alias using the `DISTRO_PN_ALIAS` variable.

Following is an example that shows how you specify the `DISTRO_PN_ALIAS` variable:

         DISTRO_PN_ALIAS_pn-PACKAGENAME = "distro1=package_name_alias1 \
                                           distro2=package_name_alias2 \
                                           distro3=package_name_alias3 \
                                           ..."

If you have more than one distribution alias, separate them with a space. Note that the Yocto Project currently automatically checks the Fedora, OpenSuSE, Debian, Ubuntu, and Mandriva distributions for source package recipes without having to specify them using the `DISTRO_PN_ALIAS` variable. For example, the following command generates a report that lists the Linux distributions that include the sources for each of the Yocto Project recipes.

         $ bitbake world -f -c distro_check

The results are stored in the `build/tmp/log/distro_check-${DATETIME}.results` file found in the Yocto Project files area.

## Building Software from an External Source

By default, the Yocto Project build system does its work from within the Yocto Project Build Directory. The build process involves fetching the source files, unpacking them, and then patching them if necessary before the build takes place.

Situations exist where you might want to build software from source files that are external to and thus outside of the Yocto Project Files. For example, suppose you have a project that includes a new BSP with a heavily customized kernel, a very minimal image, and some new user-space recipes. And, you want to minimize the exposure to the Yocto Project build system to the development team so that they can focus on their project and maintain everyone's workflow as much as possible. In this case, you want a kernel source directory on the development machine where the development occurs. You want the recipe's `SRC_URI` variable to point to the external directory and use it as is, not copy it.

To build from software that comes from an external source, all you need to do is change your recipe so that it inherits the `externalsrc.bbclass` class and then sets the `S` variable to point to your external source code. Here are the statements to put in your recipe:

         inherit externalsrc
         S = "/some/path/to/your/package/source"

It is important to know that the `externalsrc.bbclass` assumes that the source directory `S` and the build directory `B` are different even though by default these directories are the same. This assumption is important because it supports building different variants of the recipe by using the `BBCLASSEXTEND` variable. You could allow the build directory to be the same as the source directory but you would not be able to build more than one variant of the recipe. Consequently, if you are building multiple variants of the recipe, you need to establish a build directory that is different than the source directory.

## Excluding Recipes From the Build

You might find that there are groups of recipes you want to filter out of the build process. For example, recipes you know you will never use or want should not be part of the build. Removing these recipes from parsing speeds up parts of the build.

It is possible to filter or mask out `.bb` and `.bbappend` files. You can do this by providing an expression with the `BBMASK` variable. Here is an example:

         BBMASK = ".*/meta-mymachine/recipes-maybe/"

Here, all `.bb` and `.bbappend` files in the directory that match the expression are ignored during the build process.