1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
|
/*
* Copyright (c) 2011 Aeroflex Gaisler
*
* BSD license:
*
* Permission is hereby granted, free of charge, to any person obtaining a copy
* of this software and associated documentation files (the "Software"), to deal
* in the Software without restriction, including without limitation the rights
* to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
* copies of the Software, and to permit persons to whom the Software is
* furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in
* all copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
* THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
* THE SOFTWARE.
*/
#include <asm-leon/leon.h>
#include <asm-leon/leonstack.h>
#include <asm-leon/asmmacro.h>
.seg "data"
.global _lb_spillglobals, _lb_issideflush
.align 4
_lb_spillglobals:
.word 0
.word 0
.word 0
.word 0
.word 0
.word 0
.word 0
_lb_issideflush:
.word 0 /* off: 28 */
.seg "text"
/* =============================================== */
#define _SV save %sp, -SF_REGS_SZ, %sp
#define _RS restore
/* ------- */
.weak _flush_windows
.set _flush_windows,__flush_windows
.weak _flush_windows_svt
.set _flush_windows_svt,__flush_windows_svt
/* ------- */
!.global _flush_windows,_flush_windows_svt
__flush_windows_svt:
rd %wim, %l3
__flush_windows:
SAVE_ALL
#ifndef _FLAT
set _lb_issideflush, %l3
st %l0, [%l3] /* mark as inside flush */
wr %l0, SPARC_PSR_ET_MASK, %psr
nop; nop; nop
_SV; _SV; _SV; _SV; _SV; _SV; _SV;
_RS; _RS; _RS; _RS; _RS; _RS; _RS;
set _lb_issideflush, %l3
st %g0, [%l3] /* mark as outside flush */
/* Advance over the trap instruction. */
ld [%sp + SF_REGS_SZ + PT_NPC], %l1
add %l1, 0x4, %l2
st %l1, [%sp + SF_REGS_SZ + PT_PC]
st %l2, [%sp + SF_REGS_SZ + PT_NPC]
#endif
RESTORE_ALL
/* =============================================== */
_irqcall_flush_windows:
#ifndef _FLAT
set _lb_spillglobals,%l4
st %g1,[%l4+0]
st %g4,[%l4+4]
st %l0,[%l4+16]
st %l1,[%l4+20]
st %l2,[%l4+24]
st %l4,[%l4+28] /* mark as inside flush */
restore
mov %psr, %g1
or %g1, SPARC_PSR_PIL_MASK, %g1
wr %g1, SPARC_PSR_ET_MASK, %psr /* disable irq, enable traps */
nop
nop
nop
sethi %hi(_nwindows_min1), %g4 /* flush registers */
ld [%g4+%lo(_nwindows_min1)], %g4
1: save /* NWINDOWS-1 times */
sub %g4,1,%g4
/*****************/
andncc %g4,0xff,%g0
be .lab1
nop
nop
.lab1: /*****************/
cmp %g4,%g0
bne 1b
nop
sethi %hi(_nwindows_min1), %g4
ld [%g4+%lo(_nwindows_min1)], %g4
2: restore /* NWINDOWS-1 times */
/*****************/
andncc %g4,0xff,%g0
be .lab2
nop
nop
.lab2: /*****************/
sub %g4,1,%g4
cmp %g4,%g0
bne 2b
nop
save
set _lb_spillglobals,%l4
ld [%l4+4], %g4
ld [%l4+0], %g1
ld [%l4+16],%l0
ld [%l4+20],%l1
ld [%l4+24],%l2
st %g0,[%l4+28] /* clean inside flush mark */
#endif
wr %l0, 0, %psr /* restore psr */
nop
nop
nop
jmpl %l2, %g0
rett %l2 + 4
/* =============================================== */
/* ------- */
.weak _irqcall_disableirq
.set _irqcall_disableirq,__irqcall_disableirq
.weak _irqcall_disableirq_svt
.set _irqcall_disableirq_svt,__irqcall_disableirq_svt
/* ------- */
__irqcall_disableirq:
__irqcall_disableirq_svt:
or %l0, SPARC_PSR_PIL_MASK, %l0
mov %l0, %psr
nop; nop; nop
jmpl %l2, %g0
rett %l2 + 4
/* =============================================== */
/*
* system call (ta 0x2):
* 2: irq_disable:
* o1 = 2
* 3: irq_enable:
* o0 = old_flags
* o1 = 3
* 4: enter supervisor mode (from user mode):
* o1 = 4
* 5: enter user mode:
* o1 = 5
* 6: flush windows
*
* On entry:
*
* l0 = psr (from trap table)
* l1 = pc
* l2 = npc
* i0 = system call id
*/
/* ------- */
.weak _irqcall
.set _irqcall,__irqcall
.weak _irqcall_svt
.set _irqcall_svt,__irqcall_svt
/* ------- */
!.global _irqcall,_irqcall_svt
__irqcall_svt:
__irqcall:
subcc %i1, 2, %g0 ! syscall 2, disable interrupts
bne 3f
or %l0, 0x0f00, %l4 ! set PIL=15
mov %l4, %psr
or %l0, SPARC_PSR_ET_MASK, %i0 ! return old psr with ET=1
ba,a 9f
3:
subcc %i1, 3, %g0 ! syscall 3, enable interrupts
bne 4f
and %i0, SPARC_PSR_PIL_MASK, %l4
andn %l0, SPARC_PSR_PIL_MASK, %l5
or %l5, %l4, %l4
mov %l4, %psr
ba,a 9f
4:
subcc %i1, 4, %g0 ! syscall 4, enter supervisor
bne 5f
mov %psr, %l4
or %l4,SPARC_PSR_PS_MASK,%l4
mov %l4, %psr ! set previous supervisor %psr
nop; nop; nop
ba,a 9f
5:
subcc %i1, 5, %g0 ! syscall 5, enter user
bne 6f
mov %psr, %l4
andn %l4,SPARC_PSR_PS_MASK,%l4
mov %l4, %psr ! clear previous supervisor %psr, return to user mode
nop; nop; nop
ba,a 9f
6:
subcc %i1, 6, %g0 ! syscall 6, flush windows
bne 1f
nop
ba,a _irqcall_flush_windows
1:
ta 0 ! halt
9: ! leave
jmpl %l2, %g0
rett %l2 + 4
/* =============================================== */
/* call _irqcall through trap */
.global leonbare_enable_traps !void leonbare_enable_traps(unsigned long old_flags);
leonbare_enable_traps:
set 3,%o1
retl
ta 0x2
/* =============================================== */
/* call _irqcall through trap */
.global leonbare_disable_traps !unsigned long leonbare_disable_traps();
leonbare_disable_traps:
set 2,%o1
retl
ta 0x2
/* =============================================== */
/* flush all windows */
.global leonbare_flush_windows !void leonbare_flush_windows();
leonbare_flush_windows:
set 6,%o1
retl
ta 0x2
|
