1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
|
/* strcspn (str, ss) -- Return the length of the initial segment of STR
which contains no characters from SS.
For SPARC v9.
Copyright (C) 1999 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Jakub Jelinek <jj@ultra.linux.cz>
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Library General Public License as
published by the Free Software Foundation; either version 2 of the
License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Library General Public License for more details.
You should have received a copy of the GNU Library General Public
License along with the GNU C Library; see the file COPYING.LIB. If not,
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
Boston, MA 02111-1307, USA. */
#include <sysdep.h>
#include <asm/asi.h>
#ifndef XCC
#define XCC xcc
#define STACK_SIZE 128
#define STACK_OFFSET 128+0x7ff
#else
#define STACK_SIZE 64
#define STACK_OFFSET 64
#endif
.text
.align 32
ENTRY(strcspn)
sub %sp, STACK_SIZE+32, %sp /* IEU0 Group */
mov 1, %o4 /* IEU1 */
stx %o4, [%sp + STACK_OFFSET] /* Store Group */
mov %o0, %g7 /* IEU0 */
stx %g0, [%sp + STACK_OFFSET + 8] /* Store Group */
add %sp, STACK_OFFSET, %o5 /* IEU0 */
stx %g0, [%sp + STACK_OFFSET + 16] /* Store Group */
stx %g0, [%sp + STACK_OFFSET + 24] /* Store Group */
1: ldub [%o1], %o2 /* Load Group */
brz,pn %o2, 2f /* CTI+IEU1 Group */
srl %o2, 3, %o3 /* IEU0 */
and %o3, 0x18, %o3 /* IEU0 Group */
and %o2, 0x3f, %o2 /* IEU1 */
ldx [%o5 + %o3], %g2 /* Load Group */
sllx %o4, %o2, %g1 /* IEU0 */
add %o1, 1, %o1 /* IEU1 */
or %g2, %g1, %g2 /* IEU0 Group */
ba,pt %xcc, 1b /* CTI */
stx %g2, [%o5 + %o3] /* Store */
2: andcc %o0, 7, %g0 /* IEU1 Group */
be,a,pt %xcc, 4f /* CTI */
ldx [%o0], %o2 /* Load */
ldub [%o0], %o2 /* Load Group */
3: srl %o2, 3, %o3 /* IEU0 Group */
and %o2, 0x3f, %o2 /* IEU1 */
and %o3, 0x18, %o3 /* IEU0 Group */
ldx [%o5 + %o3], %g2 /* Load Group */
sllx %o4, %o2, %g1 /* IEU0 */
add %o0, 1, %o0 /* IEU1 */
andcc %g2, %g1, %g0 /* IEU1 Group */
bne,pn %xcc, 12f /* CTI */
andcc %o0, 7, %g0 /* IEU1 Group */
bne,a,pt %icc, 3b /* CTI */
ldub [%o0], %o2 /* Load */
ldx [%o0], %o2 /* Load Group */
4: srlx %o2, 59, %o3 /* IEU0 Group */
srlx %o2, 56, %g3 /* IEU0 Group */
5: and %o3, 0x18, %o3 /* IEU1 */
andcc %g3, 0x3f, %g3 /* IEU1 Group */
ldx [%o5 + %o3], %g2 /* Load */
srlx %o2, 51, %o3 /* IEU0 */
sllx %o4, %g3, %g1 /* IEU0 Group */
srlx %o2, 48, %g3 /* IEU0 Group */
andcc %g2, %g1, %g2 /* IEU1 */
bne,pn %xcc, 13f /* CTI */
and %o3, 0x18, %o3 /* IEU0 Group */
and %g3, 0x3f, %g3 /* IEU1 */
ldx [%o5 + %o3], %g2 /* Load Group */
srlx %o2, 43, %o3 /* IEU0 */
sllx %o4, %g3, %g1 /* IEU0 Group */
srlx %o2, 40, %g3 /* IEU0 Group */
andcc %g2, %g1, %g2 /* IEU1 */
bne,pn %xcc, 14f /* CTI */
and %o3, 0x18, %o3 /* IEU0 Group */
and %g3, 0x3f, %g3 /* IEU1 */
ldx [%o5 + %o3], %g2 /* Load Group */
srlx %o2, 35, %o3 /* IEU0 */
sllx %o4, %g3, %g1 /* IEU0 Group */
srlx %o2, 32, %g3 /* IEU0 Group */
andcc %g2, %g1, %g2 /* IEU1 */
bne,pn %xcc, 15f /* CTI */
and %o3, 0x18, %o3 /* IEU0 Group */
and %g3, 0x3f, %g3 /* IEU1 */
ldx [%o5 + %o3], %g2 /* Load Group */
srlx %o2, 27, %o3 /* IEU0 */
sllx %o4, %g3, %g1 /* IEU0 Group */
srlx %o2, 24, %g3 /* IEU0 Group */
andcc %g2, %g1, %g2 /* IEU1 */
bne,pn %xcc, 16f /* CTI */
and %o3, 0x18, %o3 /* IEU0 Group */
and %g3, 0x3f, %g3 /* IEU1 */
ldx [%o5 + %o3], %g2 /* Load Group */
srlx %o2, 19, %o3 /* IEU0 */
sllx %o4, %g3, %g1 /* IEU0 Group */
srlx %o2, 16, %g3 /* IEU0 Group */
andcc %g2, %g1, %g2 /* IEU1 */
bne,pn %xcc, 17f /* CTI */
and %o3, 0x18, %o3 /* IEU0 Group */
and %g3, 0x3f, %g3 /* IEU1 */
ldx [%o5 + %o3], %g2 /* Load Group */
srlx %o2, 11, %o3 /* IEU0 */
sllx %o4, %g3, %g1 /* IEU0 Group */
add %o0, 8, %o0 /* IEU1 */
srlx %o2, 8, %g3 /* IEU0 Group */
andcc %g2, %g1, %g2 /* IEU1 */
bne,pn %xcc, 18f /* CTI */
and %o3, 0x18, %o3 /* IEU0 Group */
and %g3, 0x3f, %g3 /* IEU1 */
ldx [%o5 + %o3], %g2 /* Load Group */
sllx %o4, %g3, %g1 /* IEU0 */
mov %o2, %g3 /* IEU1 */
srlx %o2, 3, %o3 /* IEU0 Group */
ldxa [%o0] ASI_PNF, %o2 /* Load */
andcc %g2, %g1, %g2 /* IEU1 Group */
bne,pn %xcc, 19f /* CTI */
and %o3, 0x18, %o3 /* IEU0 Group */
and %g3, 0x3f, %g3 /* IEU1 */
ldx [%o5 + %o3], %g2 /* Load Group */
sllx %o4, %g3, %g1 /* IEU0 */
srlx %o2, 59, %o3 /* IEU0 Group */
andcc %g2, %g1, %g2 /* IEU1 Group */
be,pt %xcc, 5b /* CTI */
srlx %o2, 56, %g3 /* IEU0 Group */
sub %o0, 1, %o0 /* IEU1 */
add %sp, STACK_SIZE+32, %sp /* IEU0 Group */
retl /* CTI+IEU1 Group */
sub %o0, %g7, %o0 /* IEU0 */
.align 16
19: sub %o0, 2, %o0 /* IEU1 */
add %sp, STACK_SIZE+32, %sp /* IEU0 Group */
retl /* CTI+IEU1 Group */
sub %o0, %g7, %o0 /* IEU0 */
18: sub %o0, 3, %o0 /* IEU1 */
add %sp, STACK_SIZE+32, %sp /* IEU0 Group */
retl /* CTI+IEU1 Group */
sub %o0, %g7, %o0 /* IEU0 */
17: add %o0, 4, %o0 /* IEU1 */
add %sp, STACK_SIZE+32, %sp /* IEU0 Group */
retl /* CTI+IEU1 Group */
sub %o0, %g7, %o0 /* IEU0 */
16: add %o0, 3, %o0 /* IEU1 */
add %sp, STACK_SIZE+32, %sp /* IEU0 Group */
retl /* CTI+IEU1 Group */
sub %o0, %g7, %o0 /* IEU0 */
15: add %o0, 2, %o0 /* IEU1 */
add %sp, STACK_SIZE+32, %sp /* IEU0 Group */
retl /* CTI+IEU1 Group */
sub %o0, %g7, %o0 /* IEU0 */
14: add %o0, 1, %o0 /* IEU1 */
add %sp, STACK_SIZE+32, %sp /* IEU0 Group */
retl /* CTI+IEU1 Group */
sub %o0, %g7, %o0 /* IEU0 */
13: add %sp, STACK_SIZE+32, %sp /* IEU1 */
retl /* CTI+IEU1 Group */
sub %o0, %g7, %o0 /* IEU0 */
.align 16
12: sub %o0, 1, %o0 /* IEU0 Group */
add %sp, STACK_SIZE+32, %sp /* IEU1 */
retl /* CTI+IEU1 Group */
sub %o0, %g7, %o0 /* IEU0 */
END(strcspn)
|
