Sun May 26 15:15:08 1996 Roland McGrath <roland@delasyd.gnu.ai.mit.edu>

	* stdlib/ldiv.c: Deansideclized.

Sun May 26 19:39:53 1996  Ulrich Drepper  <drepper@cygnus.com>

	* intl/loadmsgcat.c (_nl_load_domain): Test correct variable
	after malloc.

	* string/Makefile (tester-ENV): New variable to suppress message
 	translation in test.

	* string/tester.c: Add tests for strtok_r and strsep.

	* sysdeps/i386/i486/strcat.S: Correct some more 8bit operation
	<-> 32 bit operand conflicts.

	* sysdeps/i386/strsep.S: Wrapper around <sysdeps/i386/strtok.S>
	to produce strsep function.
	* sysdeps/i386/strtok.S: Optimized implementation of strtok
	function.
	* sysdeps/i386/strtok_r.S: Wrapper around <sysdeps/i386/strtok.S>
	to produce strtok_r function.

	* sysdeps/generic/strtok.c: Moved here from string/strtok.c.
	Corrected example in comment.

	* string/Makefile (routines): Add strtok_r.
	* sysdeps/generic/strtok_r.c: New file.  Implement reentrant version
	of strtok_r.
	* string/string.h: Add prototype for strtok_r.
	* wcsmbs/wcstok.c: Handle illegal SAVE_PTR argument the same
	as in strtok_r.

Sun May 26 13:28:23 1996  Roland McGrath  <roland@delasyd.gnu.ai.mit.edu>

	* time/tzset.c (__tzset): Ignore leading : in $TZ; always try tzfile
	first and fall back to 1003.1 syntax only if it fails.

	* time/Makefile (install-others): Also install posix/ZONE and
	right/ZONE for each ZONE in $(zonenames).
	(z.% rule): Generate rules for right/ZONE and posix/ZONE targets too,
	the difference begin leapseconds vs /dev/null as 3rd dep.  For
	original ZONE targets use $(leapseconds), to be set in Makeconfig.
	(target-zone-flavor): New variable.
	(tzcompile): Use it to get the right -d for posix/ and right/ flavors.
	* Makeconfig (leapseconds): New variable.

	* mach/Machrules (%.udeps rule): Depend on Machrules.
	Emit deps for .uh and .__h files.
	(%.uh, %.__h rules): Don't depend on %.defs; use #include <$*.defs>
	instead.

Sun May 26 01:06:47 1996  Ulrich Drepper  <drepper@cygnus.com>

	* stdlib/Makefile (routines): Add llabs, lldiv.
	* stdlib/llabs.c: New file.  Implementation of return
	absolute value of long long argument.
	* stdlib/lldiv.c: New file.  Implementation of division with remainder
	of long long argument.
	* stdlib/stdlib.h [__USE_GNU] (lldiv_t): New type for lldiv
	function.
	Define prototypes for lldiv and llabs functions.

	* locale/C-collate.c: Initialize _NL_COLLATE_NRULES element.

	* stdlib/strtod.c: Replace wchar_t with wint_t.  The later is
	really the type for a single wide character.

	* string/strxfrm.c (print_val): Define separate version for
	use as wcsxfrm.  Here we don't need UTF8 encoding.

	* wcsmbs/wchar.h:  gcc-2.7.2-960517 finally introduces wint_t
	in <stddef.h>.  Use this value and only for older gcc version
	define in place.
	(uwchar_t): Remove definition.

	* wcsmbs/wcscmp.c, wcsmbs/wcscoll.c, wcsmbs/wcsncmp.c,
	wcsmbs/wcsxfrm.c, wcsmbs/wmemcmp.c: : Don't use uwchar_t as unsigned
	type.  wint_t is intended for this.

Sat May 25 14:10:19 1996  Roland McGrath  <roland@delasyd.gnu.ai.mit.edu>

	* sysdeps/unix/bsd/direntry.h: Use [1] instead of [0] for d_name to
	quiet -ansi -pedantic.
	* sysdeps/unix/common/direntry.h: Likewise.

	* login/Makefile (headers): Add lastlog.h.
	* login/lastlog.h: New file.

	* login/Makefile (CFLAGS): Don't append -D_THREAD_SAFE.
	* login/utmp.h [_REENTRANT || _THREAD_SAFE]: Replace this conditional
	with #ifdef __USE_REENTRANT.

	* features.h (__GNU_LIBRARY__): Set to 6.
	[_GNU_SOURCE] (_POSIX_SOURCE, _POSIX_C_SOURCE, _BSD_SOURCE,
	_SVID_SOURCE): Make sure they are all defined.

	* sysdeps/unix/sysv/linux/gnu/types.h: Instead of including
	<linux/posix_types.h>, define _LINUX_TYPES_DONT_EXPORT and then
	include <linux/types.h>.

	* resource/sys/resource.h: Remove trailing commas from enums.

	* sysdeps/generic/netinet/in.h: Remove trailing commas from enums.
	* sysdeps/unix/sysv/linux/netinet/in.h: Likewise.

4 files changed, 345 insertions, 10 deletions

diff --git a/sysdeps/i386/i486/strcat.S b/sysdeps/i386/i486/strcat.S
index e3d2181..081a797 100644
--- a/sysdeps/i386/i486/strcat.S
+++ b/sysdeps/i386/i486/strcat.S
@@ -1,6 +1,6 @@
 /* strcat(dest, src) -- Append SRC on the end of DEST.
 For Intel 80x86, x>=4.
-Copyright (C) 1994, 1995 Free Software Foundation, Inc.
+Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
 Contributed by Ulrich Drepper <drepper@ipd.info.uni-karlsruhe.de>.
 Optimised a little by Alan Modra <Alan@SPRI.Levels.UniSA.Edu.Au>
 This file is part of the GNU C Library.
@@ -40,19 +40,19 @@ ENTRY (strcat)
 	jz L8			/* yes => return */
 
 	/* Test the first bytes separately until destination is aligned.  */
-	testb $3, %edx		/* destination pointer aligned? */
+	testl $3, %edx		/* destination pointer aligned? */
 	jz L1			/* yes => begin scan loop */
 	testb $0xff, (%edx)	/* is end of string? */
 	jz L2			/* yes => start appending */
 	incl %edx		/* increment source pointer */
 
-	testb $3, %edx		/* destination pointer aligned? */
+	testl $3, %edx		/* destination pointer aligned? */
 	jz L1			/* yes => begin scan loop */
 	testb $0xff, (%edx)	/* is end of string? */
 	jz L2			/* yes => start appending */
 	incl %edx		/* increment source pointer */
 
-	testb $3, %edx		/* destination pointer aligned? */
+	testl $3, %edx		/* destination pointer aligned? */
 	jz L1			/* yes => begin scan loop */
 	testb $0xff, (%edx)	/* is end of string? */
 	jz L2			/* yes => start appending */
@@ -152,27 +152,27 @@ L3:	testb %al, %al		/* is first byte NUL? */
 L2:	subl %ecx, %edx		/* reduce number of loop variants */
 
 	/* Now we have to align the source pointer.  */
-	testb $3, %ecx		/* pointer correctly aligned? */
+	testl $3, %ecx		/* pointer correctly aligned? */
 	jz L29			/* yes => start copy loop */
 	movb (%ecx), %al	/* get first byte */
 	movb %al, (%ecx,%edx)	/* and store it */
-	andl %al, %al		/* is byte NUL? */
+	andb %al, %al		/* is byte NUL? */
 	jz L8			/* yes => return */
 	incl %ecx		/* increment pointer */
 
-	testb $3, %ecx		/* pointer correctly aligned? */
+	testl $3, %ecx		/* pointer correctly aligned? */
 	jz L29			/* yes => start copy loop */
 	movb (%ecx), %al	/* get first byte */
 	movb %al, (%ecx,%edx)	/* and store it */
-	andl %al, %al		/* is byte NUL? */
+	andb %al, %al		/* is byte NUL? */
 	jz L8			/* yes => return */
 	incl %ecx		/* increment pointer */
 
-	testb $3, %ecx		/* pointer correctly aligned? */
+	testl $3, %ecx		/* pointer correctly aligned? */
 	jz L29			/* yes => start copy loop */
 	movb (%ecx), %al	/* get first byte */
 	movb %al, (%ecx,%edx)	/* and store it */
-	andl %al, %al		/* is byte NUL? */
+	andb %al, %al		/* is byte NUL? */
 	jz L8			/* yes => return */
 	incl %ecx		/* increment pointer */
 
diff --git a/sysdeps/i386/strsep.S b/sysdeps/i386/strsep.S
new file mode 100644
index 0000000..8c425dd
--- /dev/null
+++ b/sysdeps/i386/strsep.S
@@ -0,0 +1,3 @@
+#define FUNCTION strsep
+#define USE_AS_STRSEP	1
+#include <sysdeps/i386/strtok.S>
diff --git a/sysdeps/i386/strtok.S b/sysdeps/i386/strtok.S
new file mode 100644
index 0000000..28845e0
--- /dev/null
+++ b/sysdeps/i386/strtok.S
@@ -0,0 +1,329 @@
+/* strtok (str, delim) -- Return next DELIM separated token from STR.
+For Intel 80x86, x>=3.
+Copyright (C) 1996 Free Software Foundation, Inc.
+This file is part of the GNU C Library.
+Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
+
+The GNU C Library is free software; you can redistribute it and/or
+modify it under the terms of the GNU Library General Public License as
+published by the Free Software Foundation; either version 2 of the
+License, or (at your option) any later version.
+
+The GNU C Library is distributed in the hope that it will be useful,
+but WITHOUT ANY WARRANTY; without even the implied warranty of
+MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+Library General Public License for more details.
+
+You should have received a copy of the GNU Library General Public
+License along with the GNU C Library; see the file COPYING.LIB.  If
+not, write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+Boston, MA 02111-1307, USA.  */
+
+#include <errnos.h>
+#include <sysdep.h>
+
+/* This file can be used for three variants of the strtok function:
+
+   strtok:
+	INPUT PARAMETER:
+	str		(sp + 4)
+	delim		(sp + 8)
+
+   strtok_r:
+	INPUT PARAMETER:
+	str		(sp + 4)
+	delim		(sp + 8)
+	save_ptr	(sp + 12)
+
+   strsep:
+	INPUT PARAMETERS
+	str_ptr		(sp + 4)
+	delim		(sp + 8)
+
+   We do a common implementation here.  */
+
+#if !defined (USE_AS_STRTOK_R) && !defined (USE_AS_STRSEP)
+	.bss
+	.local save_ptr
+	ASM_TYPE_DIRECTIVE (save_ptr, @object)
+	.size save_ptr, 4
+save_ptr:
+	.space 4
+
+#define FUNCTION strtok
+#endif
+
+	/* We use the possibility to do some more initialization
+	   for the strtok implementation.  */
+	.text
+Lillegal_argument:
+#ifndef PIC
+	movl $EINVAL, C_SYMBOL_NAME(errno)
+	xorl %eax, %eax
+#else
+# if defined (USE_AS_STRTOK_R) || defined (USE_AS_STRSEP)
+	pushl %ebx			/* Save PIC register.  */
+	call Lhere2
+Lhere2:	popl %ebx
+	addl $_GLOBAL_OFFSET_TABLE_+[.-Lhere2], %ebx
+# endif
+	movl errno@GOT(%ebx), %ebx
+	movl $EINVAL, (%ebx)
+	xorl %eax, %eax
+	popl %ebx
+#endif
+	ret
+
+
+ENTRY (FUNCTION)
+
+	movl 4(%esp), %edx		/* Get start of string.  */
+	movl 8(%esp), %eax		/* Get start of delimiter set.  */
+
+#ifdef USE_AS_STRSEP
+	/* %EDX does not yet contain the string starting point.  Only
+	   a pointer to the location where it is stored.  */
+	movl (%edx), %edx
+#else
+# if !defined (USE_AS_STRTOK_R) && defined (PIC)
+	pushl %ebx			/* Save PIC register.  */
+	call Lhere
+Lhere:	popl %ebx
+	addl $_GLOBAL_OFFSET_TABLE_+[.-Lhere], %ebx
+# endif
+
+	/* If the pointer is NULL we have to use the stored value of
+	   the last run.  */
+	cmpl $0, %edx
+	jne L0
+
+# ifdef USE_AS_STRTOK_R
+	/* The value is stored in the third argument.  */
+	movl 12(%esp), %edx
+	movl (%edx), %edx
+# else
+	/* The value is in the local variable defined above.  But
+	   we have to take care for PIC code.  */
+#  ifndef PIC
+	movl save_ptr, %edx
+#  else
+	movl save_ptr@GOTOFF(%ebx), %edx
+#  endif
+# endif
+#endif
+
+	/* Compare whether pointer is NULL.  We are tolerant here
+	   because the C function do the same.  */
+	cmpl $0, %edx
+	je Lillegal_argument
+
+#ifndef USE_AS_STRSEP
+L0:
+#endif
+	/* First we create a table with flags for all possible characters.
+	   For the ASCII (7bit/8bit) or ISO-8859-X character sets which are
+	   supported by the C string functions we have 256 characters.
+	   Before inserting marks for the stop characters we clear the whole
+	   table.  The unrolled form is much faster than a loop.  */
+	xorl %ecx, %ecx		/* %ecx = 0 !!! */
+
+	pushl %ecx		/* make a 256 bytes long block filled with 0 */
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl %ecx
+	pushl $0		/* These immediate values make the label 2 */
+	pushl $0		/* to be aligned on a 16 byte boundary to */
+	pushl $0		/* get a better performance of the loop.  */
+	pushl $0
+	pushl $0
+	pushl $0
+
+/* For understanding the following code remember that %ecx == 0 now.
+   Although all the following instruction only modify %cl we always
+   have a correct zero-extended 32-bit value in %ecx.  */
+
+L2:	movb (%eax), %cl	/* get byte from stopset */
+	testb %cl, %cl		/* is NUL char? */
+	jz L1			/* yes => start compare loop */
+	movb %cl, (%esp,%ecx)	/* set corresponding byte in stopset table */
+
+	movb 1(%eax), %cl	/* get byte from stopset */
+	testb $0xff, %cl	/* is NUL char? */
+	jz L1			/* yes => start compare loop */
+	movb %cl, (%esp,%ecx)	/* set corresponding byte in stopset table */
+
+	movb 2(%eax), %cl	/* get byte from stopset */
+	testb $0xff, %cl	/* is NUL char? */
+	jz L1			/* yes => start compare loop */
+	movb %cl, (%esp,%ecx)	/* set corresponding byte in stopset table */
+
+	movb 3(%eax), %cl	/* get byte from stopset */
+	addl $4, %eax		/* increment stopset pointer */
+	movb %cl, (%esp,%ecx)	/* set corresponding byte in stopset table */
+	testb $0xff, %cl	/* is NUL char? */
+	jnz L2			/* no => process next dword from stopset */
+
+L1:	leal -4(%edx), %eax	/* prepare loop */
+
+	/* We use a neat trick for the following loop.  Normally we would
+	   have to test for two termination conditions
+	   1. a character in the stopset was found
+	   and
+	   2. the end of the string was found
+	   But as a sign that the chracter is in the stopset we store its
+	   value in the table.  But the value of NUL is NUL so the loop
+	   terminates for NUL in every case.  */
+
+L3:	addl $4, %eax		/* adjust pointer for full loop round */
+
+	movb (%eax), %cl	/* get byte from string */
+	testb %cl, (%esp,%ecx)	/* is it contained in stopset? */
+	jz L4			/* no => start of token */
+
+	movb 1(%eax), %cl	/* get byte from string */
+	testb %cl, (%esp,%ecx)	/* is it contained in stopset? */
+	jz L5			/* no => start of token */
+
+	movb 2(%eax), %cl	/* get byte from string */
+	testb %cl, (%esp,%ecx)	/* is it contained in stopset? */
+	jz L6			/* no => start of token */
+
+	movb 3(%eax), %cl	/* get byte from string */
+	testb %cl, (%esp,%ecx)	/* is it contained in stopset? */
+	jnz L3			/* yes => start of loop */
+
+	incl %eax		/* adjust pointer */
+L6:	incl %eax
+L5:	incl %eax
+
+	/* Now we have to terminate the string.  */
+
+L4:	leal -4(%eax), %edx	/* We use %EDX for the next run.  */
+
+L7:	addl $4, %edx		/* adjust pointer for full loop round */
+
+	movb (%edx), %cl	/* get byte from string */
+	cmpb %cl, (%esp,%ecx)	/* is it contained in skipset? */
+	je L8			/* yes => return */
+
+	movb 1(%edx), %cl	/* get byte from string */
+	cmpb %cl, (%esp,%ecx)	/* is it contained in skipset? */
+	je L9			/* yes => return */
+
+	movb 2(%edx), %cl	/* get byte from string */
+	cmpb %cl, (%esp,%ecx)	/* is it contained in skipset? */
+	je L10			/* yes => return */
+
+	movb 3(%edx), %cl	/* get byte from string */
+	cmpb %cl, (%esp,%ecx)	/* is it contained in skipset? */
+	jne L7			/* no => start loop again */
+
+	incl %edx		/* adjust pointer */
+L10:	incl %edx
+L9:	incl %edx
+
+L8:	/* Remove the stopset table.  */
+	addl $256, %esp
+
+	cmpl %eax, %edx
+	je LreturnNULL		/* There was no token anymore.  */
+
+	movb $0, (%edx)		/* Terminate string.  */
+
+	/* Are we at end of string?  */
+	cmpb $0, %cl
+	je L11
+
+	incl %edx
+L11:
+
+	/* Store the pointer to the next character.  */
+#ifdef USE_AS_STRTOK_R
+	movl 12(%esp), %ecx
+	movl %edx, (%ecx)
+#elif USE_AS_STRSEP
+	movl 4(%esp), %ecx
+	movl %edx, (%ecx)
+#else
+# ifndef PIC
+	movl %edx, save_ptr
+# else
+	movl %edx, save_ptr@GOTOFF(%ebx)
+	popl %ebx
+# endif
+#endif
+	ret
+
+LreturnNULL:
+	xorl %eax, %eax
+
+	/* Store NULL as pointer to the next character.  */
+#ifdef USE_AS_STRTOK_R
+	movl 12(%esp), %ecx
+	movl %eax, (%ecx)
+#elif USE_AS_STRSEP
+	movl 4(%esp), %ecx
+	movl %eax, (%ecx)
+#else
+# ifndef PIC
+	movl %eax, save_ptr
+# else
+	movl %eax, save_ptr@GOTOFF(%ebx)
+	popl %ebx
+# endif
+#endif
+	ret
diff --git a/sysdeps/i386/strtok_r.S b/sysdeps/i386/strtok_r.S
new file mode 100644
index 0000000..297ba28
--- /dev/null
+++ b/sysdeps/i386/strtok_r.S
@@ -0,0 +1,3 @@
+#define FUNCTION strtok_r
+#define USE_AS_STRTOK_R	1
+#include <sysdeps/i386/strtok.S>