Add gdbsupport check-defines script

This adds a new script that tries to check that none of the support
code uses defines that are not defined by common.m4.  This check is
necessarily inexact, but this script caught all the issues fixed in
the previous patches.

gdbsupport/ChangeLog
2020-01-14  Tom Tromey  <tom@tromey.com>

	* Makefile.in: Rebuild.
	* Makefile.am (check-defines): New target.
	* check-defines.el: New file.

Change-Id: I59450e91394d5e6a7fa59e9ab53c95843c4bacd9

4 files changed, 91 insertions, 0 deletions

diff --git a/gdbsupport/ChangeLog b/gdbsupport/ChangeLog
index 96a458d..aa82736 100644
--- a/gdbsupport/ChangeLog
+++ b/gdbsupport/ChangeLog
@@ -1,5 +1,11 @@
 2020-01-14  Tom Tromey  <tom@tromey.com>
 
+	* Makefile.in: Rebuild.
+	* Makefile.am (check-defines): New target.
+	* check-defines.el: New file.
+
+2020-01-14  Tom Tromey  <tom@tromey.com>
+
 	* configure, Makefile.in, aclocal.m4, common.m4, config.in:
 	Rebuild.
 	* common.m4 (GDB_AC_COMMON): Move many checks from
diff --git a/gdbsupport/Makefile.am b/gdbsupport/Makefile.am
index 48e6079..1a001a0 100644
--- a/gdbsupport/Makefile.am
+++ b/gdbsupport/Makefile.am
@@ -68,3 +68,7 @@ libgdbsupport_a_SOURCES = \
     thread-pool.c \
     xml-utils.c	\
     $(selftest)
+
+# Double-check that no defines are missing from our configury.
+check-defines:
+	cd $(srcdir) && emacs --script check-defines.el
diff --git a/gdbsupport/Makefile.in b/gdbsupport/Makefile.in
index a2e174d..5723ae5 100644
--- a/gdbsupport/Makefile.in
+++ b/gdbsupport/Makefile.in
@@ -691,6 +691,10 @@ uninstall-am:
 override CC := $(CXX)
 override CFLAGS := $(CXXFLAGS)
 
+# Double-check that no defines are missing from our configury.
+check-defines:
+	cd $(srcdir) && emacs --script check-defines.el
+
 # Tell versions [3.59,3.63) of GNU make to not export all variables.
 # Otherwise a system limit (for SysV at least) may be exceeded.
 .NOEXPORT:
diff --git a/gdbsupport/check-defines.el b/gdbsupport/check-defines.el
new file mode 100644
index 0000000..b59748f
--- /dev/null
+++ b/gdbsupport/check-defines.el
@@ -0,0 +1,77 @@
+;; Verify that preprocessor symbols are defined in config.in.
+
+;; Copyright (C) 2020 Free Software Foundation, Inc.
+;;
+;; This file is part of GDB.
+;;
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 3 of the License, or
+;; (at your option) any later version.
+;;
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+;;
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+;; To use:
+;;   cd gdbsupport
+;;   emacs --script check-defines.el
+
+(require 'cl-lib)
+
+(setq-default case-fold-search nil)
+
+;; The currently recognized macros.
+(defconst check-regexp "\\_<\\(\\(HAVE\\|PTRACE_TYPE\\|SIZEOF\\)_[a-zA-Z0-9_]+\\)\\_>")
+
+(defvar check-seen 0)
+
+;; Whitelist.  These are things that have names like autoconf-created
+;; macros, but that are managed directly in the code.
+(put (intern "HAVE_USEFUL_SBRK") :check-ok t)
+(put (intern "HAVE_SOCKETS") :check-ok t)
+(put (intern "HAVE_F_GETFD") :check-ok t)
+(put (intern "HAVE_IS_TRIVIALLY_COPYABLE") :check-ok t)
+(put (intern "HAVE_IS_TRIVIALLY_CONSTRUCTIBLE") :check-ok t)
+(put (intern "HAVE_DOS_BASED_FILE_SYSTEM") :check-ok t)
+
+(defun check-read-config.in (file)
+  (save-excursion
+    (find-file-read-only file)
+    (goto-char (point-min))
+    (while (re-search-forward "^#undef \\(.+\\)$" nil t)
+      (let ((name (match-string 1)))
+	(put (intern name) :check-ok t)))))
+
+(defun check-one-file (file)
+  (save-excursion
+    (find-file-read-only file)
+    (goto-char (point-min))
+    (while (re-search-forward check-regexp nil t)
+      (let ((name (match-string 1)))
+	(unless (get (intern name) :check-ok)
+	  (save-excursion
+	    (goto-char (match-beginning 0))
+	    (cl-incf check-seen)
+	    (message "%s:%d:%d: error: name %s not defined"
+		     file
+		     (line-number-at-pos)
+		     (current-column)
+		     name)))))))
+
+(defun check-directory (dir)
+  (dolist (file (directory-files dir t "\\.[ch]$"))
+    (check-one-file file)))
+
+(check-read-config.in "config.in")
+(check-read-config.in "../gnulib/config.in")
+(check-directory ".")
+(check-directory "../gdb/nat")
+(check-directory "../gdb/target")
+
+(when (> check-seen 0)
+  (message "%d errors seen" check-seen))