1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
dnl Process this file with autoconf to produce a configure script.
AC_INIT(db/db.c)
AC_CONFIG_HEADER(include/config.h include/db-config.h)
CONFIG_RULES
AC_PROG_INSTALL
AC_PATH_PROG(FALSE,false,:)
AC_PATH_PROG(SH,sh,$FALSE)
AC_PATH_PROG(SH5,sh5,$FALSE)
AC_PATH_PROG(BASH,bash,$FALSE)
AC_CACHE_CHECK([checking for shell with functions],local_cv_program_fctsh,
[if $SH -c 'foo() { true; }; foo' > /dev/null 2>&1; then
local_cv_program_fctsh=$SH
else
if $SH5 -c 'foo() { true; }; foo' > /dev/null 2>&1; then
local_cv_program_fctsh=$SH5
else
if $BASH -c 'foo() { true; }; foo' > /dev/null 2>&1; then
local_cv_program_fctsh=$BASH
else
local_cv_program_fctsh=$FALSE
fi
fi
fi])
FCTSH=$local_cv_program_fctsh
AC_SUBST(FCTSH)
dnl checks for libraries
dnl checks for header files
AC_CHECK_HEADERS(unistd.h stdint.h inttypes.h)
dnl checks for typedefs
AC_TYPE_SIZE_T
dnl AC_COMPILE_TYPE(TYPE, DEFAULT)
AC_DEFUN(AC_COMPILE_TYPE,
[AC_REQUIRE([AC_HEADER_STDC])dnl
AC_MSG_CHECKING(for $1)
AC_CACHE_VAL(ac_cv_type_$1,
[AC_TRY_COMPILE([#include <sys/types.h>
#if STDC_HEADERS
#include <stdlib.h>
#endif], [$1 test_variable;], ac_cv_type_$1=yes, ac_cv_type_$1=no)])dnl
AC_MSG_RESULT($ac_cv_type_$1)
if test $ac_cv_type_$1 = no; then
AC_DEFINE($1, $2, [Define to \`$2' if not defined on system])
fi
])
AC_CHECK_TYPE(ssize_t, int)
AC_CHECK_TYPE(u_char, unsigned char)
AC_CHECK_TYPE(u_int, unsigned int)
AC_CHECK_TYPE(u_long, unsigned long)
AC_CHECK_TYPE(int8_t, signed char)
AC_CHECK_TYPE(u_int8_t, unsigned char)
AC_CHECK_TYPE(int16_t, short)
AC_CHECK_TYPE(u_int16_t, unsigned short)
AC_COMPILE_TYPE(int32_t, int)
AC_COMPILE_TYPE(u_int32_t, unsigned int)
dnl checks for structures
dnl checks for compiler characteristics
AC_C_BIGENDIAN
AC_C_CONST
AC_CHECK_SIZEOF(int)
dnl checks for library functions
AC_CHECK_FUNC(memmove, ,
[MEMMOVE_OBJ=memmove.o
AC_DEFINE(memmove, kdb2__memmove,[Define to kdb2__memmove to provide private memmove function])
AC_DEFINE(MEMMOVE,1,[Define if memmove.o is compiled in])])
AC_SUBST(MEMMOVE_OBJ)
AC_CHECK_FUNC(mkstemp, ,
[MKSTEMP_OBJ=mkstemp.o
AC_DEFINE(mkstemp, kdb2__mkstemp,[Define to \`kdb2__mkstemp' to provide private mkstemp function])])
AC_SUBST(MKSTEMP_OBJ)
AC_CHECK_FUNC(strerror, ,
[STRERROR_OBJ=strerror.o
AC_DEFINE(strerror, kdb2__strerror,[Define to \`kdb2__strerror' to provide private strerror function])])
AC_SUBST(STRERROR_OBJ)
KRB5_BUILD_LIBRARY
KRB5_BUILD_LIBOBJS
KRB5_BUILD_PROGRAM
KRB5_RUN_FLAGS
K5_GEN_MAKEFILE(., lib)
K5_GEN_MAKEFILE(hash, libobj)
K5_GEN_MAKEFILE(btree, libobj)
K5_GEN_MAKEFILE(db, libobj)
K5_GEN_MAKEFILE(mpool, libobj)
K5_GEN_MAKEFILE(recno, libobj)
K5_GEN_MAKEFILE(clib, libobj)
K5_GEN_MAKEFILE(test)
K5_AC_OUTPUT
|
