1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
|
// Test the default control-flow sink pass.
// RUN: mlir-opt -control-flow-sink %s | FileCheck %s
// Test that operations can be sunk.
// CHECK-LABEL: @test_simple_sink
// CHECK-SAME: (%[[ARG0:.*]]: i32, %[[ARG1:.*]]: i32, %[[ARG2:.*]]: i32)
// CHECK-NEXT: %[[V0:.*]] = arith.subi %[[ARG2]], %[[ARG1]]
// CHECK-NEXT: %[[V1:.*]] = test.region_if %[[ARG0]]: i32 -> i32 then {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: %[[V2:.*]] = arith.subi %[[ARG1]], %[[ARG2]]
// CHECK-NEXT: test.region_if_yield %[[V2]]
// CHECK-NEXT: } else {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: %[[V2:.*]] = arith.addi %[[ARG1]], %[[ARG1]]
// CHECK-NEXT: %[[V3:.*]] = arith.addi %[[V0]], %[[V2]]
// CHECK-NEXT: test.region_if_yield %[[V3]]
// CHECK-NEXT: } join {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: %[[V2:.*]] = arith.addi %[[ARG2]], %[[ARG2]]
// CHECK-NEXT: %[[V3:.*]] = arith.addi %[[V2]], %[[V0]]
// CHECK-NEXT: test.region_if_yield %[[V3]]
// CHECK-NEXT: }
// CHECK-NEXT: return %[[V1]]
func.func @test_simple_sink(%arg0: i32, %arg1: i32, %arg2: i32) -> i32 {
%0 = arith.subi %arg1, %arg2 : i32
%1 = arith.subi %arg2, %arg1 : i32
%2 = arith.addi %arg1, %arg1 : i32
%3 = arith.addi %arg2, %arg2 : i32
%4 = test.region_if %arg0: i32 -> i32 then {
^bb0(%arg3: i32):
test.region_if_yield %0 : i32
} else {
^bb0(%arg3: i32):
%5 = arith.addi %1, %2 : i32
test.region_if_yield %5 : i32
} join {
^bb0(%arg3: i32):
%5 = arith.addi %3, %1 : i32
test.region_if_yield %5 : i32
}
return %4 : i32
}
// Test that a region op can be sunk.
// CHECK-LABEL: @test_region_sink
// CHECK-SAME: (%[[ARG0:.*]]: i32, %[[ARG1:.*]]: i32, %[[ARG2:.*]]: i32)
// CHECK-NEXT: %[[V0:.*]] = test.region_if %[[ARG0]]: i32 -> i32 then {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: %[[V1:.*]] = test.region_if %[[ARG0]]: i32 -> i32 then {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG1]]
// CHECK-NEXT: } else {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: %[[V2:.*]] = arith.subi %[[ARG1]], %[[ARG2]]
// CHECK-NEXT: test.region_if_yield %[[V2]]
// CHECK-NEXT: } join {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG2]]
// CHECK-NEXT: }
// CHECK-NEXT: test.region_if_yield %[[V1]]
// CHECK-NEXT: } else {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG1]]
// CHECK-NEXT: } join {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG2]]
// CHECK-NEXT: }
// CHECK-NEXT: return %[[V0]]
func.func @test_region_sink(%arg0: i32, %arg1: i32, %arg2: i32) -> i32 {
%0 = arith.subi %arg1, %arg2 : i32
%1 = test.region_if %arg0: i32 -> i32 then {
^bb0(%arg3: i32):
test.region_if_yield %arg1 : i32
} else {
^bb0(%arg3: i32):
test.region_if_yield %0 : i32
} join {
^bb0(%arg3: i32):
test.region_if_yield %arg2 : i32
}
%2 = test.region_if %arg0: i32 -> i32 then {
^bb0(%arg3: i32):
test.region_if_yield %1 : i32
} else {
^bb0(%arg3: i32):
test.region_if_yield %arg1 : i32
} join {
^bb0(%arg3: i32):
test.region_if_yield %arg2 : i32
}
return %2 : i32
}
// Test that an entire subgraph can be sunk.
// CHECK-LABEL: @test_subgraph_sink
// CHECK-SAME: (%[[ARG0:.*]]: i32, %[[ARG1:.*]]: i32, %[[ARG2:.*]]: i32)
// CHECK-NEXT: %[[V0:.*]] = test.region_if %[[ARG0]]: i32 -> i32 then {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: %[[V1:.*]] = arith.subi %[[ARG1]], %[[ARG2]]
// CHECK-NEXT: %[[V2:.*]] = arith.addi %[[ARG1]], %[[ARG2]]
// CHECK-NEXT: %[[V3:.*]] = arith.subi %[[ARG2]], %[[ARG1]]
// CHECK-NEXT: %[[V4:.*]] = arith.muli %[[V3]], %[[V3]]
// CHECK-NEXT: %[[V5:.*]] = arith.muli %[[V2]], %[[V1]]
// CHECK-NEXT: %[[V6:.*]] = arith.addi %[[V5]], %[[V4]]
// CHECK-NEXT: test.region_if_yield %[[V6]]
// CHECK-NEXT: } else {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG1]]
// CHECK-NEXT: } join {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG2]]
// CHECK-NEXT: }
// CHECK-NEXT: return %[[V0]]
func.func @test_subgraph_sink(%arg0: i32, %arg1: i32, %arg2: i32) -> i32 {
%0 = arith.addi %arg1, %arg2 : i32
%1 = arith.subi %arg1, %arg2 : i32
%2 = arith.subi %arg2, %arg1 : i32
%3 = arith.muli %0, %1 : i32
%4 = arith.muli %2, %2 : i32
%5 = arith.addi %3, %4 : i32
%6 = test.region_if %arg0: i32 -> i32 then {
^bb0(%arg3: i32):
test.region_if_yield %5 : i32
} else {
^bb0(%arg3: i32):
test.region_if_yield %arg1 : i32
} join {
^bb0(%arg3: i32):
test.region_if_yield %arg2 : i32
}
return %6 : i32
}
// Test that ops can be sunk into regions with multiple blocks.
// CHECK-LABEL: @test_multiblock_region_sink
// CHECK-SAME: (%[[ARG0:.*]]: i32, %[[ARG1:.*]]: i32, %[[ARG2:.*]]: i32)
// CHECK-NEXT: %[[V0:.*]] = arith.addi %[[ARG1]], %[[ARG2]]
// CHECK-NEXT: %[[V1:.*]] = "test.any_cond"() ({
// CHECK-NEXT: %[[V3:.*]] = arith.addi %[[V0]], %[[ARG2]]
// CHECK-NEXT: %[[V4:.*]] = arith.addi %[[V3]], %[[ARG1]]
// CHECK-NEXT: cf.br ^bb1(%[[V4]] : i32)
// CHECK-NEXT: ^bb1(%[[V5:.*]]: i32):
// CHECK-NEXT: %[[V6:.*]] = arith.addi %[[V5]], %[[V4]]
// CHECK-NEXT: "test.yield"(%[[V6]])
// CHECK-NEXT: })
// CHECK-NEXT: %[[V2:.*]] = arith.addi %[[V0]], %[[V1]]
// CHECK-NEXT: return %[[V2]]
func.func @test_multiblock_region_sink(%arg0: i32, %arg1: i32, %arg2: i32) -> i32 {
%0 = arith.addi %arg1, %arg2 : i32
%1 = arith.addi %0, %arg2 : i32
%2 = arith.addi %1, %arg1 : i32
%3 = "test.any_cond"() ({
cf.br ^bb1(%2 : i32)
^bb1(%5: i32):
%6 = arith.addi %5, %2 : i32
"test.yield"(%6) : (i32) -> ()
}) : () -> i32
%4 = arith.addi %0, %3 : i32
return %4 : i32
}
// Test that ops can be sunk recursively into nested regions.
// CHECK-LABEL: @test_nested_region_sink
// CHECK-SAME: (%[[ARG0:.*]]: i32, %[[ARG1:.*]]: i32) -> i32 {
// CHECK-NEXT: %[[V0:.*]] = test.region_if %[[ARG0]]: i32 -> i32 then {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: %[[V1:.*]] = test.region_if %[[ARG0]]: i32 -> i32 then {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: %[[V2:.*]] = arith.addi %[[ARG1]], %[[ARG1]]
// CHECK-NEXT: test.region_if_yield %[[V2]]
// CHECK-NEXT: } else {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG1]]
// CHECK-NEXT: } join {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG1]]
// CHECK-NEXT: }
// CHECK-NEXT: test.region_if_yield %[[V1]]
// CHECK-NEXT: } else {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG1]]
// CHECK-NEXT: } join {
// CHECK-NEXT: ^bb0(%{{.*}}: i32):
// CHECK-NEXT: test.region_if_yield %[[ARG1]]
// CHECK-NEXT: }
// CHECK-NEXT: return %[[V0]]
func.func @test_nested_region_sink(%arg0: i32, %arg1: i32) -> i32 {
%0 = arith.addi %arg1, %arg1 : i32
%1 = test.region_if %arg0: i32 -> i32 then {
^bb0(%arg3: i32):
%2 = test.region_if %arg0: i32 -> i32 then {
^bb0(%arg4: i32):
test.region_if_yield %0 : i32
} else {
^bb0(%arg4: i32):
test.region_if_yield %arg1 : i32
} join {
^bb0(%arg4: i32):
test.region_if_yield %arg1 : i32
}
test.region_if_yield %2 : i32
} else {
^bb0(%arg3: i32):
test.region_if_yield %arg1 : i32
} join {
^bb0(%arg3: i32):
test.region_if_yield %arg1 : i32
}
return %1 : i32
}
// Test that ops are only moved into the entry block, even when their only uses
// are further along.
// CHECK-LABEL: @test_not_sunk_deeply
// CHECK-SAME: (%[[ARG0:.*]]: i32) -> i32 {
// CHECK-NEXT: %[[V0:.*]] = "test.any_cond"() ({
// CHECK-NEXT: %[[V1:.*]] = arith.addi %[[ARG0]], %[[ARG0]]
// CHECK-NEXT: cf.br ^bb1
// CHECK-NEXT: ^bb1:
// CHECK-NEXT: "test.yield"(%[[V1]]) : (i32) -> ()
// CHECK-NEXT: })
// CHECK-NEXT: return %[[V0]]
func.func @test_not_sunk_deeply(%arg0: i32) -> i32 {
%0 = arith.addi %arg0, %arg0 : i32
%1 = "test.any_cond"() ({
cf.br ^bb1
^bb1:
"test.yield"(%0) : (i32) -> ()
}) : () -> i32
return %1 : i32
}
|
