1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
|
/* Optimized strcmp implementation for POWER7/PowerPC32.
Copyright (C) 2010-2017 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, see
<http://www.gnu.org/licenses/>. */
#include <sysdep.h>
/* See strlen.s for comments on how the end-of-string testing works. */
/* int [r3] strncmp (const char *s1 [r3],
const char *s2 [r4],
size_t size [r5]) */
EALIGN (strncmp,5,0)
#define rTMP2 r0
#define rRTN r3
#define rSTR1 r3 /* first string arg */
#define rSTR2 r4 /* second string arg */
#define rN r5 /* max string length */
#define rWORD1 r6 /* current word in s1 */
#define rWORD2 r7 /* current word in s2 */
#define rWORD3 r10
#define rWORD4 r11
#define rFEFE r8 /* constant 0xfefefeff (-0x01010101) */
#define r7F7F r9 /* constant 0x7f7f7f7f */
#define rNEG r10 /* ~(word in s1 | 0x7f7f7f7f) */
#define rBITDIF r11 /* bits that differ in s1 & s2 words */
#define rTMP r12
dcbt 0,rSTR1
nop
or rTMP,rSTR2,rSTR1
lis r7F7F,0x7f7f
dcbt 0,rSTR2
nop
clrlwi. rTMP,rTMP,30
cmplwi cr1,rN,0
lis rFEFE,-0x101
bne L(unaligned)
/* We are word aligned so set up for two loops. first a word
loop, then fall into the byte loop if any residual. */
srwi. rTMP,rN,2
clrlwi rN,rN,30
addi rFEFE,rFEFE,-0x101
addi r7F7F,r7F7F,0x7f7f
cmplwi cr1,rN,0
beq L(unaligned)
mtctr rTMP
lwz rWORD1,0(rSTR1)
lwz rWORD2,0(rSTR2)
b L(g1)
L(g0):
lwzu rWORD1,4(rSTR1)
bne cr1,L(different)
lwzu rWORD2,4(rSTR2)
L(g1): add rTMP,rFEFE,rWORD1
nor rNEG,r7F7F,rWORD1
bdz L(tail)
and. rTMP,rTMP,rNEG
cmpw cr1,rWORD1,rWORD2
beq L(g0)
/* OK. We've hit the end of the string. We need to be careful that
we don't compare two strings as different because of gunk beyond
the end of the strings... */
#ifdef __LITTLE_ENDIAN__
L(endstring):
slwi rTMP, rTMP, 1
addi rTMP2, rTMP, -1
andc rTMP2, rTMP2, rTMP
and rWORD2, rWORD2, rTMP2 /* Mask off gunk. */
and rWORD1, rWORD1, rTMP2
rlwinm rTMP2, rWORD2, 8, 0xffffffff /* Byte reverse word. */
rlwinm rTMP, rWORD1, 8, 0xffffffff
rldimi rTMP2, rWORD2, 24, 32
rldimi rTMP, rWORD1, 24, 32
rlwimi rTMP2, rWORD2, 24, 16, 23
rlwimi rTMP, rWORD1, 24, 16, 23
xor. rBITDIF, rTMP, rTMP2
sub rRTN, rTMP, rTMP2
bgelr
ori rRTN, rTMP2, 1
blr
L(different):
lwz rWORD1, -4(rSTR1)
rlwinm rTMP2, rWORD2, 8, 0xffffffff /* Byte reverse word. */
rlwinm rTMP, rWORD1, 8, 0xffffffff
rldimi rTMP2, rWORD2, 24, 32
rldimi rTMP, rWORD1, 24, 32
rlwimi rTMP2, rWORD2, 24, 16, 23
rlwimi rTMP, rWORD1, 24, 16, 23
xor. rBITDIF, rTMP, rTMP2
sub rRTN, rTMP, rTMP2
bgelr
ori rRTN, rTMP2, 1
blr
#else
L(endstring):
and rTMP,r7F7F,rWORD1
beq cr1,L(equal)
add rTMP,rTMP,r7F7F
xor. rBITDIF,rWORD1,rWORD2
andc rNEG,rNEG,rTMP
blt L(highbit)
cntlzw rBITDIF,rBITDIF
cntlzw rNEG,rNEG
addi rNEG,rNEG,7
cmpw cr1,rNEG,rBITDIF
sub rRTN,rWORD1,rWORD2
bgelr cr1
L(equal):
li rRTN,0
blr
L(different):
lwz rWORD1,-4(rSTR1)
xor. rBITDIF,rWORD1,rWORD2
sub rRTN,rWORD1,rWORD2
bgelr
L(highbit):
ori rRTN, rWORD2, 1
blr
#endif
/* Oh well. In this case, we just do a byte-by-byte comparison. */
.align 4
L(tail):
and. rTMP,rTMP,rNEG
cmpw cr1,rWORD1,rWORD2
bne L(endstring)
addi rSTR1,rSTR1,4
bne cr1,L(different)
addi rSTR2,rSTR2,4
cmplwi cr1,rN,0
L(unaligned):
mtctr rN
ble cr1,L(ux)
L(uz):
lbz rWORD1,0(rSTR1)
lbz rWORD2,0(rSTR2)
.align 4
L(u1):
cmpwi cr1,rWORD1,0
bdz L(u4)
cmpw rWORD1,rWORD2
beq cr1,L(u4)
bne L(u4)
lbzu rWORD3,1(rSTR1)
lbzu rWORD4,1(rSTR2)
cmpwi cr1,rWORD3,0
bdz L(u3)
cmpw rWORD3,rWORD4
beq cr1,L(u3)
bne L(u3)
lbzu rWORD1,1(rSTR1)
lbzu rWORD2,1(rSTR2)
cmpwi cr1,rWORD1,0
bdz L(u4)
cmpw rWORD1,rWORD2
beq cr1,L(u4)
bne L(u4)
lbzu rWORD3,1(rSTR1)
lbzu rWORD4,1(rSTR2)
cmpwi cr1,rWORD3,0
bdz L(u3)
cmpw rWORD3,rWORD4
beq cr1,L(u3)
bne L(u3)
lbzu rWORD1,1(rSTR1)
lbzu rWORD2,1(rSTR2)
b L(u1)
L(u3): sub rRTN,rWORD3,rWORD4
blr
L(u4): sub rRTN,rWORD1,rWORD2
blr
L(ux):
li rRTN,0
blr
END (strncmp)
libc_hidden_builtin_def (strncmp)
|
