libc.map


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

GLIBC_2.0 {
  global:
    # global variables
    _errno; _itoa_lower_digits; _itoa_upper_digits;
    __ctype_b; __ctype_tolower; __ctype_toupper;
    _IO_stderr_; _IO_stdin_; _IO_stdout_;
    _nl_msg_cat_cntr; __environ; _environ; _res;
    ___brk_addr; __curbrk; _nl_current_LC_CTYPE; _libc_intl_domainname;

    # helper functions
    __errno_location; __libc_init_first; __h_errno_location;

    # functions with special/multiple interfaces
    __sigsetjmp; _setjmp; __sigaddset; __sigdelset; __sigismember;
    __sysv_signal; __bsd_getpgrp;

    # functions which have an additional interface since they are
    # are cancelable.
    __libc_wait; __libc_waitpid; __libc_pause; __libc_nanosleep;
    __libc_open; __libc_close; __libc_read; __libc_write;
    __libc_lseek; __libc_fcntl; __libc_tcdrain; __libc_fsync;
    __libc_msync; __libc_system;

    # interface of malloc functions
    __libc_calloc; __libc_free; __libc_mallinfo; __libc_malloc;
    __libc_mallopt; __libc_memalign; __libc_pvalloc; __libc_realloc;
    __libc_valloc;

    # functions with required interface outside normal name space
    _exit; __ivaliduser;

    # functions from the experimental locale implementation
    __*_l; __newlocale; __duplocale; __freelocale;

    # functions used in inline functions or macros
    __strto*_internal; __wcsto*_internal; __getdelim;
    __isnan; __isnanf; __isnanl; __finite; __finitef; __finitel;
    __isinf; __isinff; __isinfl;
    __signbit; __signbitf; __signbitl; __cmsg_nxthdr;
    _obstack_allocated_p; _obstack_begin; _obstack_begin_1;
    _obstack_free; _obstack_memory_used; _obstack_newchunk;
    __assert_fail; __assert_perror_fail;
    _IO_getc; _IO_peekc_unlocked; _IO_putc; _IO_feof; _IO_ferror;

    # functions used in other libraries
    __printf_fp; __stpncpy; _dcgettext;
    _nss_files_parse_grent; _nss_files_parse_pwent; _nss_files_parse_spent;
    __nss_database_lookup; __internal_endnetgrent; __internal_getnetgrent_r;
    __internal_setnetgrent; __gmtime_r; __secure_getenv;
    __select; __sched_get_priority_max; __sched_get_priority_min;
    __sched_getparam; __sched_getscheduler; __sched_setscheduler;
    __sched_yield; __on_exit; __gettimeofday; __fork; __clone;

    # all functions and variables in the normal name space
    a*; b*; c*; d*; e*; f*; g*; h*; i*; j*; k*; l*; m*;
    n*; o*; p*; q*; r*; s*; t*; u*; v*; w*; x*; y*; z*;

  local:
    *;
};