Update.cvs/libc-ud-970629

1997-06-29 23:43  Ulrich Drepper  <drepper@cygnus.com>

	* config.make.in: Define need-nopic-initfini.
	* configure.in: Write out nopic_initfini.
	* csu/Makefile: Generate no-PIC crt code if need-nopic-initfini
	is defined.

	* sysdeps/i386/fpu/fraiseexcpt.c: Correct FE_INEXACT case.

	* sysdeps/sparc/rem.S: Get trap definition properly.
	* sysdeps/sparc/sdiv.S: Likewise.
	* sysdeps/sparc/udiv.S: Likewise.
	* sysdeps/sparc/urem.S: Likewise.
	* sysdeps/sparc/setjmp.S: Include <sys/trap.h>.
	* sysdeps/sparc/sys/trap.h: New file.
	* sysdeps/unix/sysv/linux/sparc/sys/trap.h: New file.

1997-06-25 10:26  Thorsten Kukuk  <kukuk@uni-paderborn.de>

	* sysdeps/generic/rpc/auth.h: Add xdr_opaque_auth declaration.

1997-06-29 10:34  Fila Kolodny  <fila@ibi.com>

	* sysdeps/mach/hurd/select.c (__select): Change MACH_MSG_SIZE_INTEGER_T
	to MACH_MSG_TYPE_INTEGER_T.

1997-06-29  01:04  Richard Henderson  <richard@gnu.ai.mit.edu>

	Initial sparc64-linux support:
	* configure.in: Recognize sparc64 as being different from sparc.
	* io/ftwtest-sh: Only invoke ld.so if it exists.
	* math/Makefile (LDLIBS-*): Change from libm to math/libm to get
	static tests to link.  Honour $(omit-long-double-fcts) == yes.
	* math/libm-test.c (test_single_exception): The argument to
	fetestexcept is `int' not `fexcept_t'.
	* shlib-versions: Recognize sparc64.
	* signal/signal.h: Add typedef for stack_t.

	* stdio-common/_itoa.c: Defaulting UMUL_TIME==UDIV_TIME is broken.
	Attempt to fix up most of this by cleaning up assumptions below,
	but give up and change the defaults.

	* setjmp/longjmp.c: Moved to ...
	* sysdeps/generic/longjmp.c: ... here.
	* setjmp/sigjmp.c: Moved to ...
	* sysdeps/generic/sigjmp.c: ... here.

	* sysdeps/sparc/bsd-_setjmp.S [PIC]: There wasn't even valid asm here.
	Ought to fix up gas to catch these silly things properly.
	* sysdeps/sparc/bsd-setjmp.S: Likewise.

	* sysdeps/unix/sysv/linux/sparc/errno.c: Remove.
	* sysdeps/unix/sysv/linux/sparc/kernel_sigaction.h: Remove.
	* sysdeps/unix/sysv/linux/sparc/kernel_stat.h: Tell xstat about
	the unused fields.

	* sysdeps/sparc/sparc64/add_n.s: Moved to ...
	* sysdeps/sparc64/add_n.S: ... here.  Fix up %g4 and stack usage.
	* sysdeps/sparc/sparc64/addmul_1.s: Likewise.
	* sysdeps/sparc/sparc64/gmp-mparam.h: Likewise.
	* sysdeps/sparc/sparc64/lshift.s: Likewise.
	* sysdeps/sparc/sparc64/mul_1.s: Likewise.
	* sysdeps/sparc/sparc64/rshift.s: Likewise.
	* sysdeps/sparc/sparc64/sub_n.s: Likewise.
	* sysdeps/sparc/sparc64/submul_1.s: Likewise.

	* sysdeps/sparc64/Implies: New file.
	* sysdeps/sparc64/Makefile: Likewise.
	* sysdeps/sparc64/bits/endian.h: Likewise.
	* sysdeps/sparc64/bsd-_setjmp.S: Likewise.
	* sysdeps/sparc64/bsd-setjmp.S: Likewise.
	* sysdeps/sparc64/dl-machine.h: Likewise.
	* sysdeps/sparc64/elf/Makefile: Likewise.
	* sysdeps/sparc64/elf/crtbegin.S: Likewise.
	* sysdeps/sparc64/elf/crtbeginS.S: Likewise.
	* sysdeps/sparc64/elf/crtend.S: Likewise.
	* sysdeps/sparc64/elf/crtendS.S: Likewise.
	* sysdeps/sparc64/elf/start.S: Likewise.
	* sysdeps/sparc64/fpu_control.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/Makefile: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/__longjmp.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/bits/setjmp.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/bits/types.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/brk.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/clone.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/fork.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/getcontext.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/init-first.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/kernel_stat.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/longjmp.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/pipe.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/profil-counter.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/setcontext.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/setjmp.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/sigjmp.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/syscalls.list: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/sysdep.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/sysdep.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/ucontext.h: Likewise.

1997-06-28 16:28  H.J. Lu  <hjl@gnu.ai.mit.edu>

	* configure.in: Add -nostartfiles -nostdlib when check for
	--version-script.

1997-06-28 12:03  H.J. Lu  <hjl@gnu.ai.mit.edu>

	* sysdeps/powerpc/bits/endian.h: New file.

1997-06-28 20:52  Ulrich Drepper  <drepper@cygnus.com>

	* sysdeps/unix/sysv/linux/syscalls.list: Add getresgid and
	setresgid.

23 files changed, 1281 insertions, 0 deletions

diff --git a/sysdeps/sparc64/Implies b/sysdeps/sparc64/Implies
new file mode 100644
index 0000000..1d793f9
--- /dev/null
+++ b/sysdeps/sparc64/Implies
@@ -0,0 +1,3 @@
+wordsize-64
+# SPARC uses IEEE 754 floating point.
+ieee754
diff --git a/sysdeps/sparc64/Makefile b/sysdeps/sparc64/Makefile
new file mode 100644
index 0000000..48a86c6
--- /dev/null
+++ b/sysdeps/sparc64/Makefile
@@ -0,0 +1,11 @@
+# The Sparc`long double' is a distinct type we support.
+#long-double-fcts = yes
+
+# But the support for ieee quads is so bad we just skip the whole thing.
+# XXX This is only a temporary hack.
+omit-long-double-fcts = yes
+
+# But we do need these few functions to even link stdio proggies
+ifeq ($(subdir),math)
+sysdep_routines += s_isinfl s_isnanl
+endif
diff --git a/sysdeps/sparc64/add_n.S b/sysdeps/sparc64/add_n.S
new file mode 100644
index 0000000..68bb008
--- /dev/null
+++ b/sysdeps/sparc64/add_n.S
@@ -0,0 +1,58 @@
+/* SPARC v9 __mpn_add_n -- Add two limb vectors of the same length > 0 and
+   store sum in a third limb vector.
+  
+   Copyright (C) 1995, 1996, 1997 Free Software Foundation, Inc.
+
+   This file is part of the GNU MP Library.
+
+   The GNU MP Library is free software; you can redistribute it and/or modify
+   it under the terms of the GNU Library General Public License as published by
+   the Free Software Foundation; either version 2 of the License, or (at your
+   option) any later version.
+
+   The GNU MP Library is distributed in the hope that it will be useful, but
+   WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+   or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
+   License for more details.
+
+   You should have received a copy of the GNU Library General Public License
+   along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
+   the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+   MA 02111-1307, USA.  */
+
+
+#include <sysdep.h>
+
+
+/* INPUT PARAMETERS
+   res_ptr	%o0
+   s1_ptr	%o1
+   s2_ptr	%o2
+   size		%o3  */
+
+
+ENTRY(__mpn_add_n)
+
+	sub	%g0,%o3,%g3
+	sllx	%o3,3,%g1
+	add	%o1,%g1,%o1		! make s1_ptr point at end
+	add	%o2,%g1,%o2		! make s2_ptr point at end
+	add	%o0,%g1,%o0		! make res_ptr point at end
+	mov	0,%o4			! clear carry variable
+	sllx	%g3,3,%o5		! compute initial address index
+
+1:	ldx	[%o2+%o5],%g1		! load s2 limb
+	add	%g3,1,%g3		! increment loop count
+	ldx	[%o1+%o5],%g2		! load s1 limb
+	addcc	%g1,%o4,%g1		! add s2 limb and carry variable
+	movcc	%xcc,0,%o4		! if carry-out, o4 was 1; clear it
+	addcc	%g1,%g2,%g1		! add s1 limb to sum
+	stx	%g1,[%o0+%o5]		! store result
+	add	%o5,8,%o5		! increment address index
+	brnz,pt	%g3,1b
+	 movcs	%xcc,1,%o4		! if s1 add gave carry, record it
+
+	retl
+	 mov %o4,%o0
+
+END(__mpn_add_n)
diff --git a/sysdeps/sparc64/addmul_1.S b/sysdeps/sparc64/addmul_1.S
new file mode 100644
index 0000000..2604812
--- /dev/null
+++ b/sysdeps/sparc64/addmul_1.S
@@ -0,0 +1,88 @@
+/* SPARC v9 __mpn_addmul_1 -- Multiply a limb vector with a single limb and
+   add the product to a second limb vector.
+
+   Copyright (C) 1996 Free Software Foundation, Inc.
+
+   This file is part of the GNU MP Library.
+
+   The GNU MP Library is free software; you can redistribute it and/or modify
+   it under the terms of the GNU Library General Public License as published by
+   the Free Software Foundation; either version 2 of the License, or (at your
+   option) any later version.
+
+   The GNU MP Library is distributed in the hope that it will be useful, but
+   WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+   or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
+   License for more details.
+
+   You should have received a copy of the GNU Library General Public License
+   along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
+   the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+   MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+
+/* INPUT PARAMETERS
+   res_ptr	o0
+   s1_ptr	o1
+   size		o2
+   s2_limb	o3  */
+
+
+ENTRY(__mpn_addmul_1)
+	!#PROLOGUE#	0
+	save	%sp,-128,%sp
+	!#PROLOGUE#	1
+
+	sub	%g0,%i2,%o7
+	sllx	%o7,3,%g5
+	sub	%i1,%g5,%o3
+	sub	%i0,%g5,%o4
+	mov	0,%o0			! zero cy_limb
+
+	srl	%i3,0,%o1		! extract low 32 bits of s2_limb
+	srlx	%i3,32,%i3		! extract high 32 bits of s2_limb
+	mov	1,%o2
+	sllx	%o2,32,%o2		! o2 = 0x100000000
+
+	!   hi   !
+             !  mid-1 !
+             !  mid-2 !
+		 !   lo   !
+1:
+	sllx	%o7,3,%g1
+	ldx	[%o3+%g1],%g5
+	srl	%g5,0,%i0		! zero hi bits
+	srlx	%g5,32,%g5
+	mulx	%o1,%i0,%i4		! lo product
+	mulx	%i3,%i0,%i1		! mid-1 product
+	mulx	%o1,%g5,%l2		! mid-2 product
+	mulx	%i3,%g5,%i5		! hi product
+	srlx	%i4,32,%i0		! extract high 32 bits of lo product...
+	add	%i1,%i0,%i1		! ...and add it to the mid-1 product
+	addcc	%i1,%l2,%i1		! add mid products
+	mov	0,%l0			! we need the carry from that add...
+	movcs	%xcc,%o2,%l0		! ...compute it and...
+	add	%i5,%l0,%i5		! ...add to bit 32 of the hi product
+	sllx	%i1,32,%i0		! align low bits of mid product
+	srl	%i4,0,%g5		! zero high 32 bits of lo product
+	add	%i0,%g5,%i0		! combine into low 64 bits of result
+	srlx	%i1,32,%i1		! extract high bits of mid product...
+	add	%i5,%i1,%i1		! ...and add them to the high result
+	addcc	%i0,%o0,%i0		! add cy_limb to low 64 bits of result
+	mov	0,%g5
+	movcs	%xcc,1,%g5
+	add	%o7,1,%o7
+	ldx	[%o4+%g1],%l1
+	addcc	%l1,%i0,%i0
+	movcs	%xcc,1,%g5
+	stx	%i0,[%o4+%g1]
+	brnz	%o7,1b
+	 add	%i1,%g5,%o0		! compute new cy_limb
+
+	mov	%o0,%i0
+	jmpl	%i7+8, %g0
+	 restore
+
+END(__mpn_addmul_1)
diff --git a/sysdeps/sparc64/bits/endian.h b/sysdeps/sparc64/bits/endian.h
new file mode 100644
index 0000000..a2ab072
--- /dev/null
+++ b/sysdeps/sparc64/bits/endian.h
@@ -0,0 +1,8 @@
+/* Sparc is big-endian, but v9 supports endian conversion on loads/stores
+   and GCC supports such a mode.  Be prepared.  */
+
+#ifdef __LITTLE_ENDIAN__
+#define __BYTE_ORDER __LITTLE_ENDIAN
+#else
+#define __BYTE_ORDER __BIG_ENDIAN
+#endif
diff --git a/sysdeps/sparc64/bsd-_setjmp.S b/sysdeps/sparc64/bsd-_setjmp.S
new file mode 100644
index 0000000..1388c4c
--- /dev/null
+++ b/sysdeps/sparc64/bsd-_setjmp.S
@@ -0,0 +1,43 @@
+/* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'.  Sparc64 version.
+   Copyright (C) 1997 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If not,
+   write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+   Boston, MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+ENTRY(_setjmp)
+
+#ifdef PIC
+1:	rd	%pc,%g1
+	sethi	%hi(_GLOBAL_OFFSET_TABLE_-(1b-.)),%g2
+	or	%g2,%lo(_GLOBAL_OFFSET_TABLE_-(1b-.)),%g2
+	add	%g1,%g2,%g1
+	sethi	%hi(C_SYMBOL_NAME(__sigsetjmp)),%g2
+	or	%g2,%lo(C_SYMBOL_NAME(__sigsetjmp)),%g2
+	ld	[%g1+%g2], %g1
+#else
+	sethi	%hi(C_SYMBOL_NAME(__sigsetjmp)), %g1
+	or	%lo(C_SYMBOL_NAME(__sigsetjmp)), %g1, %g1
+	add	%g1, %g4, %g1
+#endif
+
+	jmp %g1
+	 mov %g0, %o1		/* Pass second argument of zero.  */
+
+END(_setjmp)
+
+strong_alias(_setjmp, __setjmp)
diff --git a/sysdeps/sparc64/bsd-setjmp.S b/sysdeps/sparc64/bsd-setjmp.S
new file mode 100644
index 0000000..c42123f
--- /dev/null
+++ b/sysdeps/sparc64/bsd-setjmp.S
@@ -0,0 +1,41 @@
+/* BSD `setjmp' entry point to `sigsetjmp (..., 1)'.  Sparc64 version.
+   Copyright (C) 1997 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If not,
+   write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+   Boston, MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+ENTRY(setjmp)
+
+#ifdef PIC
+1:	rd	%pc,%g1
+	sethi	%hi(_GLOBAL_OFFSET_TABLE_-(1b-.)),%g2
+	or	%g2,%lo(_GLOBAL_OFFSET_TABLE_-(1b-.)),%g2
+	add	%g1,%g2,%g1
+	sethi	%hi(C_SYMBOL_NAME(__sigsetjmp)),%g2
+	or	%g2,%lo(C_SYMBOL_NAME(__sigsetjmp)),%g2
+	ld	[%g1+%g2], %g1
+#else
+	sethi	%hi(C_SYMBOL_NAME(__sigsetjmp)), %g1
+	or	%lo(C_SYMBOL_NAME(__sigsetjmp)), %g1, %g1
+	add	%g1, %g4, %g1
+#endif
+
+	jmp %g1
+	 mov 1, %o1		/* Pass second argument of one.  */
+
+END(setjmp)
diff --git a/sysdeps/sparc64/configure b/sysdeps/sparc64/configure
new file mode 100755
index 0000000..099f5b0
--- /dev/null
+++ b/sysdeps/sparc64/configure
@@ -0,0 +1,3 @@
+ # Local configure fragment for sysdeps/sparc64
+
+nopic_initfini=yes
diff --git a/sysdeps/sparc64/configure.in b/sysdeps/sparc64/configure.in
new file mode 100644
index 0000000..662f8a2
--- /dev/null
+++ b/sysdeps/sparc64/configure.in
@@ -0,0 +1,7 @@
+sinclude(./aclocal.m4)dnl Autoconf lossage
+GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
+# Local configure fragment for sysdeps/sparc64
+
+dnl We need to have separate crt? files for static linking which does
+dnl not use PIC.
+nopic_initfini=yes
\ No newline at end of file
diff --git a/sysdeps/sparc64/dl-machine.h b/sysdeps/sparc64/dl-machine.h
new file mode 100644
index 0000000..21c3d6b
--- /dev/null
+++ b/sysdeps/sparc64/dl-machine.h
@@ -0,0 +1,304 @@
+/* Machine-dependent ELF dynamic relocation inline functions.  Sparc64 version.
+   Copyright (C) 1997 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If
+   not, write to the Free Software Foundation, Inc.,
+   59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.  */
+
+#define ELF_MACHINE_NAME "sparc64"
+
+#include <assert.h>
+#include <string.h>
+#include <link.h>
+#include <sys/param.h>
+#include <sysdep.h>
+
+
+/* Return nonzero iff E_MACHINE is compatible with the running host.  */
+static inline int
+elf_machine_matches_host (Elf64_Half e_machine)
+{
+  return e_machine == EM_SPARC64;
+}
+
+
+/* Return the link-time address of _DYNAMIC.  Conveniently, this is the
+   first element of the GOT.  This must be inlined in a function which
+   uses global data.  */
+static inline Elf64_Addr
+elf_machine_dynamic (void)
+{
+  register Elf64_Addr *got asm ("%l7");
+  return *got;
+}
+
+
+/* Return the run-time load address of the shared object.  */
+static inline Elf64_Addr
+elf_machine_load_address (void)
+{
+  Elf64_Addr here;
+
+  __asm("rd %pc,%0\n\t"
+	"ba 1f\n\t"
+	" add %0,12,%0\n\t"
+	".weak __load_address_undefined\n\t"
+	"call __load_address_undefined\n"
+	"1:"
+	: "=r"(here));
+
+  return here + (*(int *)here << 2);
+}
+
+#ifdef RESOLVE
+/* Perform the relocation specified by RELOC and SYM (which is fully resolved).
+   MAP is the object containing the reloc.  */
+
+static inline void
+elf_machine_rela (struct link_map *map, const Elf64_Rela *reloc,
+		  const Elf64_Sym *sym, const struct r_found_version *version)
+{
+  Elf64_Addr *const reloc_addr = (void *) (map->l_addr + reloc->r_offset);
+  Elf64_Addr loadbase;
+
+#ifndef RTLD_BOOTSTRAP
+  /* This is defined in rtld.c, but nowhere in the static libc.a; make the
+     reference weak so static programs can still link.  This declaration
+     cannot be done when compiling rtld.c (i.e.  #ifdef RTLD_BOOTSTRAP)
+     because rtld.c contains the common defn for _dl_rtld_map, which is
+     incompatible with a weak decl in the same file.  */
+  weak_extern (_dl_rtld_map);
+#endif
+
+  if (ELF64_R_TYPE (reloc->r_info) == R_SPARC_RELATIVE)
+    {
+#ifndef RTLD_BOOTSTRAP
+      if (map != &_dl_rtld_map) /* Already done in rtld itself. */
+#endif
+	*reloc_addr += map->l_addr + reloc->r_addend;
+    }
+  else
+    {
+      const Elf64_Sym *const refsym = sym;
+      Elf64_Addr value;
+      if (sym->st_shndx != SHN_UNDEF &&
+	  ELF64_ST_BIND (sym->st_info) == STB_LOCAL)
+	value = map->l_addr;
+      else
+	{
+	  value = RESOLVE (&sym, version, ELF64_R_TYPE (reloc->r_info));
+	  if (sym)
+	    value += sym->st_value;
+	}
+      value += reloc->r_addend;	/* Assume copy relocs have zero addend.  */
+
+      switch (ELF64_R_TYPE (reloc->r_info))
+	{
+	case R_SPARC_COPY:
+	  if (sym->st_size > refsym->st_size
+	      || (_dl_verbose && sym->st_size < refsym->st_size))
+	    {
+	      const char *strtab;
+
+	      strtab = ((void *) map->l_addr
+			+ map->l_info[DT_STRTAB]->d_un.d_ptr);
+	      _dl_sysdep_error ("Symbol `", strtab + refsym->st_name,
+				"' has different size in shared object, "
+				"consider re-linking\n", NULL);
+	    }
+	  memcpy (reloc_addr, (void *) value, MIN (sym->st_size,
+						   refsym->st_size));
+	  break;
+	case R_SPARC_GLOB_DAT:
+	/* case R_SPARC_64: */
+	case R_SPARC_JMP_SLOT:
+	  *reloc_addr = value;
+	  break;
+	case R_SPARC_8:
+	  *(char *) reloc_addr = value;
+	  break;
+	case R_SPARC_16:
+	  *(short *) reloc_addr = value;
+	  break;
+	case R_SPARC_DISP8:
+	  *(char *) reloc_addr = (value - (Elf64_Addr) reloc_addr);
+	  break;
+	case R_SPARC_DISP16:
+	  *(short *) reloc_addr = (value - (Elf64_Addr) reloc_addr);
+	  break;
+	case R_SPARC_DISP32:
+	  *(unsigned int *)reloc_addr = (value - (Elf64_Addr) reloc_addr);
+	  break;
+	case R_SPARC_LO10:
+	  *(unsigned *)reloc_addr = (*(unsigned *)reloc_addr & ~0x3ff)
+				     | (value & 0x3ff);
+	  break;
+	case R_SPARC_WDISP30:
+	  *(unsigned *)reloc_addr = ((*(unsigned *)reloc_addr & 0xc0000000)
+			 | ((value - (Elf64_Addr) reloc_addr) >> 2));
+	  break;
+	case R_SPARC_HI22:
+	  *(unsigned *)reloc_addr = (*(unsigned *)reloc_addr & 0xffc00000)
+				     | (value >> 10);
+	  break;
+	case R_SPARC_NONE:		/* Alright, Wilbur.  */
+	  break;
+	default:
+	  assert (! "unexpected dynamic reloc type");
+	  break;
+	}
+    }
+}
+
+static inline void
+elf_machine_lazy_rel (struct link_map *map, const Elf64_Rela *reloc)
+{
+  switch (ELF64_R_TYPE (reloc->r_info))
+    {
+    case R_SPARC_NONE:
+      break;
+    case R_SPARC_JMP_SLOT:
+      break;
+    default:
+      assert (! "unexpected PLT reloc type");
+      break;
+    }
+}
+
+#endif	/* RESOLVE */
+
+/* Nonzero iff TYPE should not be allowed to resolve to one of
+   the main executable's symbols, as for a COPY reloc.  */
+#define elf_machine_lookup_noexec_p(type) ((type) == R_SPARC_COPY)
+
+/* Nonzero iff TYPE describes relocation of a PLT entry, so
+   PLT entries should not be allowed to define the value.  */
+#define elf_machine_lookup_noplt_p(type) ((type) == R_SPARC_JMP_SLOT)
+
+/* A reloc type used for ld.so cmdline arg lookups to reject PLT entries.  */
+#define ELF_MACHINE_RELOC_NOPLT	R_SPARC_JMP_SLOT
+
+/* The SPARC never uses Elf64_Rel relocations.  */
+#define ELF_MACHINE_NO_REL 1
+
+
+/* Set up the loaded object described by L so its unrelocated PLT
+   entries will jump to the on-demand fixup code in dl-runtime.c.  */
+
+static inline int
+elf_machine_runtime_setup (struct link_map *l, int lazy)
+{
+  Elf64_Addr *got;
+  extern void _dl_runtime_resolve (Elf64_Word);
+
+  if (l->l_info[DT_JMPREL] && lazy)
+    {
+      got = (Elf64_Addr *) (l->l_addr + l->l_info[DT_PLTGOT]->d_un.d_ptr);
+      got[1] = (Elf64_Addr) l;  /* Identify this shared object.  */
+      /* This function will get called to fix up the GOT entry indicated by
+         the offset on the stack, and then jump to the resolved address.  */
+      got[2] = (Elf64_Addr) &_dl_runtime_resolve;
+    }
+
+  return lazy;
+}
+
+/* This code is used in dl-runtime.c to call the `fixup' function
+   and then redirect to the address it returns.  */
+#define ELF_MACHINE_RUNTIME_TRAMPOLINE asm ("\
+	.globl _dl_runtime_resolve
+	.type _dl_runtime_resolve, @function
+_dl_runtime_resolve:
+	save %sp, -160, %sp
+	mov %g1, %o1
+	call fixup
+	 mov %g2, %o0
+	jmp %o0
+	 restore
+	.size _dl_runtime_resolve, .-_dl_runtime_resolve
+");
+
+/* The PLT uses Elf64_Rela relocs.  */
+#define elf_machine_relplt elf_machine_rela
+
+
+/* Mask identifying addresses reserved for the user program,
+   where the dynamic linker should not map anything.  */
+#define ELF_MACHINE_USER_ADDRESS_MASK	???
+
+/* Initial entry point code for the dynamic linker.
+   The C function `_dl_start' is the real entry point;
+   its return value is the user program's entry point.  */
+
+#define __S1(x)	#x
+#define __S(x)	__S1(x)
+
+#define RTLD_START __asm__ ( "\
+	.global _start
+	.type _start, @function
+_start:
+   /* Make room for functions to drop their arguments on the stack.  */
+	sub	%sp, 6*8, %sp
+   /* Pass pointer to argument block to _dl_start.  */
+	call	_dl_start
+	 add	 %sp," __S(STACK_BIAS) "+22*8,%o0
+	/* FALLTHRU */
+
+	.global _dl_start_user
+	.type _dl_start_user, @function
+_dl_start_user:
+   /* Load the GOT register.  */
+1:	rd	%pc,%g1
+	sethi	%hi(_GLOBAL_OFFSET_TABLE_-(1b-.)),%l7
+	or	%l2,%lo(_GLOBAL_OFFSET_TABLE_-(1b-.)),%l7
+	add	%l7,%g1,%l7
+   /* Save the user entry point address in %l0.  */
+	mov	%o0,%l0
+   /* See if we were run as a command with the executable file name as an
+      extra leading argument.  If so, adjust the stack pointer.  */
+	sethi	%hi(_dl_skip_args), %g2
+	or	%g2, %lo(_dl_skip_args), %g2
+	ld	[%l7+%g2], %i0
+	brz,pt	%i0, 2f
+	 ldx	[%sp+" __S(STACK_BIAS) "+22*8], %i1
+	sub	%i1, %i0, %i1
+	sllx	%i0, 3, %i2
+	add	%sp, %i2, %sp
+	stx	%i1, [%sp+" __S(STACK_BIAS) "+22*8]
+   /* Load _dl_default_scope[2] to pass to _dl_init_next.  */
+2:	sethi	%hi(_dl_default_scope), %g2
+	or	%g2, %lo(_dl_defalt_scope), %g2
+	add	%g2, 2*8, %g2
+	ldx	[%l7+%g2], %l1
+   /* Call _dl_init_next to return the address of an initializer to run.  */
+3:	call	_dl_init_next
+	 mov	%l1, %o0
+	brz,pn	%o0, 4f
+	 nop
+	jmpl	%o0, %o7
+	 nop
+	ba,a	3b
+   /* Clear the startup flag.  */
+4:	sethi	%hi(_dl_starting_up), %g2
+	or	%g2, %lo(_dl_starting_up), %g2
+	st	%g0, [%l7+%g2]
+   /* Pass our finalizer function to the user in %g1
+	sethi	%hi(_dl_fini), %g1
+	or	%g1, %lo(_dl_fini), %g1
+	ldx	[%l7+%g1], %g1
+   /* Jump to the user's entry point & undo the allocation of the xtra regs.  */
+	jmp	%l0
+	 add	%sp, 6*8, %sp
+	.size _dl_start_user, .-_dl_start_user");
diff --git a/sysdeps/sparc64/elf/Makefile b/sysdeps/sparc64/elf/Makefile
new file mode 100644
index 0000000..1b38355
--- /dev/null
+++ b/sysdeps/sparc64/elf/Makefile
@@ -0,0 +1,10 @@
+# The assembler on SPARC needs the -fPIC flag even when it's assembler code.
+ASFLAGS-.so = -fPIC
+
+ifeq ($(subdir), csu)
+extra-objs += crtbegin.o crtend.o crtbeginS.o crtendS.o
+install-lib += crtbegin.o crtend.o crtbeginS.o crtendS.o
+
+CPPFLAGS-crtbeginS.S = -fPIC -DPIC
+CPPFLAGS-crtendS.S = -fPIC -DPIC
+endif
diff --git a/sysdeps/sparc64/elf/crtbegin.S b/sysdeps/sparc64/elf/crtbegin.S
new file mode 100644
index 0000000..fbd731c
--- /dev/null
+++ b/sysdeps/sparc64/elf/crtbegin.S
@@ -0,0 +1,49 @@
+.section ".ctors",#alloc,#write
+
+	.align 8
+__CTOR_LIST__:
+	.xword	-1
+
+.section ".dtors",#alloc,#write
+
+	.align 8
+__DTOR_LIST__:
+	.xword	-1
+
+.section ".fini",#alloc,#execinstr
+
+	call	__do_global_dtors_aux
+	 nop
+
+.text
+
+	.align 4
+	.type __do_global_dtors_aux,#function
+__do_global_dtors_aux:
+	save	%sp,-160,%sp
+
+#ifdef PIC
+1:	rd	%pc, %g1
+	sethi	%hi(_GLOBAL_OFFSET_TABLE_-(1b-.)), %l7
+	or	%l7, %lo(_GLOBAL_OFFSET_TABLE_-(1b-.)), %l7
+	add	%l7, %g1, %l7
+	sethi	%hi(__DTOR_LIST__), %l0
+	or	%l0, %lo(__DTOR_LIST__), %l0
+	ldx	[%l7+%l0], %l0
+#else
+	sethi	%hi(__DTOR_LIST__), %l0
+	or	%l0, %lo(__DTOR_LIST__), %l0
+	add	%l0, %g4, %l0
+#endif
+
+	ba	3f
+	 ldx	[%l0+8], %l1
+2:	jmpl	%l1, %o7
+	 ldx	[%l0+8], %l1
+3:	brnz,pt	%l1, 2b
+	 add	%l0, 8, %l0
+
+	ret
+	 restore
+
+	.size __do_global_dtors_aux,.-__do_global_dtors_aux
diff --git a/sysdeps/sparc64/elf/crtbeginS.S b/sysdeps/sparc64/elf/crtbeginS.S
new file mode 100644
index 0000000..7db4bc5
--- /dev/null
+++ b/sysdeps/sparc64/elf/crtbeginS.S
@@ -0,0 +1 @@
+#include "crtbegin.S"
diff --git a/sysdeps/sparc64/elf/crtend.S b/sysdeps/sparc64/elf/crtend.S
new file mode 100644
index 0000000..ea69083
--- /dev/null
+++ b/sysdeps/sparc64/elf/crtend.S
@@ -0,0 +1,50 @@
+.section ".ctors",#alloc,#write
+
+	.align 8
+__CTOR_END__:
+	.xword	0
+
+.section ".dtors",#alloc,#write
+
+	.align 8
+__DTOR_END__:
+	.xword	0
+
+.section ".init",#alloc,#execinstr
+
+	call	__do_global_ctors_aux
+	 nop
+
+.text
+
+	.align 4
+	.type __do_global_ctors_aux,#function
+__do_global_ctors_aux:
+	save	%sp,-160,%sp
+
+#ifdef PIC
+1:	rd	%pc, %g1
+	sethi	%hi(_GLOBAL_OFFSET_TABLE_-(1b-.)), %l7
+	or	%l7, %lo(_GLOBAL_OFFSET_TABLE_-(1b-.)), %l7
+	add	%l7, %g1, %l7
+	sethi	%hi(__CTOR_END__), %l0
+	or	%l0, %lo(__CTOR_END__), %l0
+	ldx	[%l7+%l0], %l0
+#else
+	sethi	%hi(__CTOR_END__), %l0
+	or	%l0, %lo(__CTOR_END__), %l0
+	add	%l0, %g4, %l0
+#endif
+
+	ba	3f
+	 ldx	[%l0+8], %l1
+2:	jmpl	%l1, %o7
+	 ldx	[%l0+8], %l1
+3:	addcc	%l1, 1, %g0
+	bnz,pt	%xcc, 2b
+	 add	%l0, 8, %l0
+
+	ret
+	 restore
+
+	.size __do_global_ctors_aux,.-__do_global_ctors_aux
diff --git a/sysdeps/sparc64/elf/crtendS.S b/sysdeps/sparc64/elf/crtendS.S
new file mode 100644
index 0000000..56532f5
--- /dev/null
+++ b/sysdeps/sparc64/elf/crtendS.S
@@ -0,0 +1 @@
+#include "crtend.S"
diff --git a/sysdeps/sparc64/elf/start.S b/sysdeps/sparc64/elf/start.S
new file mode 100644
index 0000000..334f85b
--- /dev/null
+++ b/sysdeps/sparc64/elf/start.S
@@ -0,0 +1,93 @@
+/* Startup code for elf64-sparc
+   Copyright (C) 1997 Free Software Foundation, Inc.
+   Contributed by Richard Henderson <richard@gnu.ai.mit.edu>, 1997.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If
+   not, write to the Free Software Foundation, Inc., 675 Mass Ave,
+   Cambridge, MA 02139, USA.  */
+
+#include <sysdep.h>
+
+
+	.section ".text"
+	.align 4
+	.global _start
+	.type _start,#function
+_start:
+
+  /* First order of business is to load %g4 with our base address.  */
+	sethi	%uhi(_start), %g4
+	or	%g4, %ulo(_start), %g4
+	sllx	%g4, 32, %g4
+
+  /* Terminate the stack frame, and reserve space for functions to
+     drop their arguments.  */
+	mov	%g0, %fp
+	sub	%sp, 6*8, %sp
+
+  /* Save %g1.  When starting a binary via the dynamic linker, %g1
+     contains the address of the shared library termination function,
+     which we will register below with atexit() to be called by exit().
+     If we are statically linked, this will be NULL.  */
+
+  /* Do essential libc initialization (sp points to argc, argv, and envp)  */
+	call	__libc_init_first
+	 mov	%g1, %l0
+
+  /* Now that we have the proper stack frame, register library termination
+     function, if there is any:  */
+
+	brz,pn	%l0, 1f
+	 nop
+	call	atexit
+	 mov	%l0, %o0
+1:
+
+  /* Extract the arguments and environment as encoded on the stack.  The
+     argument info starts after one register window (16 words) past the SP,
+     plus the bias we added, plus the magic v9 STACK_BIAS.  */
+	ldx	[%sp+STACK_BIAS+22*8], %o0
+	add	%sp, STACK_BIAS+23*8, %o1
+	sllx	%o0, 3, %o2
+	add	%o2, %o1, %o2
+	sethi	%hi(__environ), %g2
+	add	%o2, 8, %o2
+	add	%g2, %g4, %g2
+	stx	%o2, [%g2+%lo(__environ)]
+
+	mov	%o0, %l0		/* tuck them away */
+	mov	%o1, %l1
+
+  /* Call _init, the entry point to our own .init section.  */
+	call	_init
+	 mov	%o2, %l2
+
+  /* Register our .fini section with atexit.  */
+	sethi	%hi(_fini), %o0
+	add	%o0, %g4, %o0
+	call	atexit
+	 add	%o0, %lo(_fini), %o0
+
+  /* Call the user's main and exit with its return value.  */
+	mov	%l0, %o0
+	mov	%l1, %o1
+	call	main
+	 mov	%l2, %o2
+	call	exit
+	 nop
+
+  /* Die very horribly if exit returns.  */
+	illtrap	0
+
+	.size _start,.-_start
diff --git a/sysdeps/sparc64/fpu_control.h b/sysdeps/sparc64/fpu_control.h
new file mode 100644
index 0000000..fd8abb1
--- /dev/null
+++ b/sysdeps/sparc64/fpu_control.h
@@ -0,0 +1,69 @@
+/* FPU control word bits.  SPARC v9 version.
+   Copyright (C) 1997 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+   Contributed by Miguel de Icaza
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If not,
+   write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+   Boston, MA 02111-1307, USA.  */
+
+#ifndef _FPU_CONTROL_H
+#define _FPU_CONTROL_H	1
+
+
+#include <features.h>
+
+/* precision control */
+#define _FPU_EXTENDED 0x00000000     /* RECOMMENDED */
+#define _FPU_DOUBLE   0x20000000
+#define _FPU_80BIT    0x30000000
+#define _FPU_SINGLE   0x10000000     /* DO NOT USE */
+
+/* rounding control / Sparc */
+#define _FPU_RC_DOWN    0xc0000000
+#define _FPU_RC_UP      0x80000000
+#define _FPU_RC_ZERO    0x40000000
+#define _FPU_RC_NEAREST 0x0        /* RECOMMENDED */
+
+#define _FPU_RESERVED   0x30300000  /* Reserved bits in cw */
+
+
+/* Now two recommended cw */
+
+/* Linux default:
+     - extended precision
+     - rounding to nearest
+     - no exceptions  */
+#define _FPU_DEFAULT  0x0
+
+/* IEEE:  same as above  */
+#define _FPU_IEEE     0x0
+
+/* Type of the control word.  */
+typedef unsigned long fpu_control_t;
+
+#define _FPU_GETCW(cw) __asm__ ("stx %%fsr,%0" : "=m" (*&cw))
+#define _FPU_SETCW(cw) __asm__ ("ldx %0,%%fsr" : : "m" (*&cw))
+
+/* Default control word set at startup.  */
+extern fpu_control_t __fpu_control;
+
+__BEGIN_DECLS
+
+/* Called at startup.  It can be used to manipulate fpu control register.  */
+extern void __setfpucw __P ((fpu_control_t));
+
+__END_DECLS
+
+#endif	/* fpu_control.h */
diff --git a/sysdeps/sparc64/gmp-mparam.h b/sysdeps/sparc64/gmp-mparam.h
new file mode 100644
index 0000000..a3c6697
--- /dev/null
+++ b/sysdeps/sparc64/gmp-mparam.h
@@ -0,0 +1,27 @@
+/* gmp-mparam.h -- Compiler/machine parameter header file.
+
+Copyright (C) 1991, 1993, 1994 Free Software Foundation, Inc.
+
+This file is part of the GNU MP Library.
+
+The GNU MP Library is free software; you can redistribute it and/or modify
+it under the terms of the GNU Library General Public License as published by
+the Free Software Foundation; either version 2 of the License, or (at your
+option) any later version.
+
+The GNU MP Library is distributed in the hope that it will be useful, but
+WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
+License for more details.
+
+You should have received a copy of the GNU Library General Public License
+along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
+the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+MA 02111-1307, USA. */
+
+#define BITS_PER_MP_LIMB 64
+#define BYTES_PER_MP_LIMB 8
+#define BITS_PER_LONGINT 64
+#define BITS_PER_INT 32
+#define BITS_PER_SHORTINT 16
+#define BITS_PER_CHAR 8
diff --git a/sysdeps/sparc64/lshift.S b/sysdeps/sparc64/lshift.S
new file mode 100644
index 0000000..1678991
--- /dev/null
+++ b/sysdeps/sparc64/lshift.S
@@ -0,0 +1,96 @@
+/* SPARC v9 __mpn_lshift --
+
+   Copyright (C) 1996 Free Software Foundation, Inc.
+
+   This file is part of the GNU MP Library.
+
+   The GNU MP Library is free software; you can redistribute it and/or modify
+   it under the terms of the GNU Library General Public License as published by
+   the Free Software Foundation; either version 2 of the License, or (at your
+   option) any later version.
+
+   The GNU MP Library is distributed in the hope that it will be useful, but
+   WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+   or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
+   License for more details.
+
+   You should have received a copy of the GNU Library General Public License
+   along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
+   the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+   MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+/* INPUT PARAMETERS
+   res_ptr	%i0
+   src_ptr	%i1
+   size		%i2
+   cnt		%i3  */
+
+ENTRY(__mpn_lshift)
+	save	%sp, -128, %sp
+
+	sllx	%i2,3,%g1
+	add	%i1,%g1,%i1	! make %i1 point at end of src
+	ldx	[%i1-8],%g2	! load first limb
+	sub	%g0,%i3,%i5	! negate shift count
+	add	%i0,%g1,%i0	! make %i0 point at end of res
+	add	%i2,-1,%i2
+	and	%i2,4-1,%l4	! number of limbs in first loop
+	srlx	%g2,%i5,%g1	! compute function result
+	brz,pn	%l4,.L0		! if multiple of 4 limbs, skip first loop
+	mov	%g1,%l1
+
+	sub	%i2,%l4,%i2	! adjust count for main loop
+
+.Loop0:	ldx	[%i1-16],%g3
+	add	%i0,-8,%i0
+	add	%i1,-8,%i1
+	add	%l4,-1,%l4
+	sllx	%g2,%i3,%i4
+	srlx	%g3,%i5,%g1
+	mov	%g3,%g2
+	or	%i4,%g1,%i4
+	brnz,pt	%l4,.Loop0
+	 stx	%i4,[%i0+0]
+
+.L0:	brz,pn	%i2,.Lend
+	 nop
+
+.Loop:	ldx	[%i1-16],%g3
+	add	%i0,-32,%i0
+	add	%i2,-4,%i2
+	sllx	%g2,%i3,%i4
+	srlx	%g3,%i5,%g1
+
+	ldx	[%i1-24],%g2
+	sllx	%g3,%i3,%l4
+	or	%i4,%g1,%i4
+	stx	%i4,[%i0+24]
+	srlx	%g2,%i5,%g1
+
+	ldx	[%i1-32],%g3
+	sllx	%g2,%i3,%i4
+	or	%l4,%g1,%l4
+	stx	%l4,[%i0+16]
+	srlx	%g3,%i5,%g1
+
+	ldx	[%i1-40],%g2
+	sllx	%g3,%i3,%l4
+	or	%i4,%g1,%i4
+	stx	%i4,[%i0+8]
+	srlx	%g2,%i5,%g1
+
+	add	%i1,-32,%i1
+	or	%l4,%g1,%l4
+	brnz,pt	%i2,.Loop
+	 stx	%l4,[%i0+0]
+
+.Lend:	sllx	%g2,%i3,%g2
+	stx	%g2,[%i0-8]
+
+	mov	%l1,%i0
+	jmpl	%i7+8, %g0
+	 restore
+
+END(__mpn_lshift)
diff --git a/sysdeps/sparc64/mul_1.S b/sysdeps/sparc64/mul_1.S
new file mode 100644
index 0000000..87e441d
--- /dev/null
+++ b/sysdeps/sparc64/mul_1.S
@@ -0,0 +1,84 @@
+/* SPARC v9 __mpn_mul_1 -- Multiply a limb vector with a single limb and
+   store the product in a second limb vector.
+
+   Copyright (C) 1995, 1996 Free Software Foundation, Inc.
+
+   This file is part of the GNU MP Library.
+
+   The GNU MP Library is free software; you can redistribute it and/or modify
+   it under the terms of the GNU Library General Public License as published by
+   the Free Software Foundation; either version 2 of the License, or (at your
+   option) any later version.
+
+   The GNU MP Library is distributed in the hope that it will be useful, but
+   WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+   or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
+   License for more details.
+
+   You should have received a copy of the GNU Library General Public License
+   along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
+   the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+   MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+
+/* INPUT PARAMETERS
+   res_ptr	o0
+   s1_ptr	o1
+   size		o2
+   s2_limb	o3  */
+
+ENTRY(__mpn_mul_1)
+	!#PROLOGUE#	0
+	save	%sp,-128,%sp
+	!#PROLOGUE#	1
+
+	sub	%g0,%i2,%o7
+	sllx	%o7,3,%g5
+	sub	%i1,%g5,%o3
+	sub	%i0,%g5,%o4
+	mov	0,%o0			! zero cy_limb
+
+	srl	%i3,0,%o1		! extract low 32 bits of s2_limb
+	srlx	%i3,32,%i3		! extract high 32 bits of s2_limb
+	mov	1,%o2
+	sllx	%o2,32,%o2		! o2 = 0x100000000
+
+	!   hi   !
+             !  mid-1 !
+             !  mid-2 !
+		 !   lo   !
+.Loop:
+	sllx	%o7,3,%g1
+	ldx	[%o3+%g1],%g5
+	srl	%g5,0,%i0		! zero hi bits
+	srlx	%g5,32,%g5
+	mulx	%o1,%i0,%i4		! lo product
+	mulx	%i3,%i0,%i1		! mid-1 product
+	mulx	%o1,%g5,%l2		! mid-2 product
+	mulx	%i3,%g5,%i5		! hi product
+	srlx	%i4,32,%i0		! extract high 32 bits of lo product...
+	add	%i1,%i0,%i1		! ...and add it to the mid-1 product
+	addcc	%i1,%l2,%i1		! add mid products
+	mov	0,%l0			! we need the carry from that add...
+	movcs	%xcc,%o2,%l0		! ...compute it and...
+	add	%i5,%l0,%i5		! ...add to bit 32 of the hi product
+	sllx	%i1,32,%i0		! align low bits of mid product
+	srl	%i4,0,%g5		! zero high 32 bits of lo product
+	add	%i0,%g5,%i0		! combine into low 64 bits of result
+	srlx	%i1,32,%i1		! extract high bits of mid product...
+	add	%i5,%i1,%i1		! ...and add them to the high result
+	addcc	%i0,%o0,%i0		! add cy_limb to low 64 bits of result
+	mov	0,%g5
+	movcs	%xcc,1,%g5
+	add	%o7,1,%o7
+	stx	%i0,[%o4+%g1]
+	brnz	%o7,.Loop
+	 add	%i1,%g5,%o0		! compute new cy_limb
+
+	mov	%o0,%i0
+	jmpl	%i7+8,%g0
+	 restore
+
+END(__mpn_mul_1)
diff --git a/sysdeps/sparc64/rshift.S b/sysdeps/sparc64/rshift.S
new file mode 100644
index 0000000..e1b3aca
--- /dev/null
+++ b/sysdeps/sparc64/rshift.S
@@ -0,0 +1,93 @@
+/* SPARC v9 __mpn_rshift --
+
+   Copyright (C) 1996 Free Software Foundation, Inc.
+
+   This file is part of the GNU MP Library.
+
+   The GNU MP Library is free software; you can redistribute it and/or modify
+   it under the terms of the GNU Library General Public License as published by
+   the Free Software Foundation; either version 2 of the License, or (at your
+   option) any later version.
+
+   The GNU MP Library is distributed in the hope that it will be useful, but
+   WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+   or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
+   License for more details.
+
+   You should have received a copy of the GNU Library General Public License
+   along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
+   the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+   MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+/* INPUT PARAMETERS
+   res_ptr	%i0
+   src_ptr	%i1
+   size		%i2
+   cnt		%i3  */
+
+ENTRY(__mpn_rshift)
+	save	%sp, -128, %sp
+
+	ldx	[%i1],%g2	! load first limb
+	sub	%g0,%i3,%i5	! negate shift count
+	add	%i2,-1,%i2
+	and	%i2,4-1,%l4	! number of limbs in first loop
+	sllx	%g2,%i5,%g1	! compute function result
+	brz,pn	%l4,.L0		! if multiple of 4 limbs, skip first loop
+	mov	%g1,%l1
+
+	sub	%i2,%l4,%i2	! adjust count for main loop
+
+.Loop0:	ldx	[%i1+8],%g3
+	add	%i0,8,%i0
+	add	%i1,8,%i1
+	add	%l4,-1,%l4
+	srlx	%g2,%i3,%i4
+	sllx	%g3,%i5,%g1
+	mov	%g3,%g2
+	or	%i4,%g1,%i4
+	brnz,pt	%l4,.Loop0
+	 stx	%i4,[%i0-8]
+
+.L0:	brz,pn	%i2,.Lend
+	 nop
+
+.Loop:	ldx	[%i1+8],%g3
+	add	%i0,32,%i0
+	add	%i2,-4,%i2
+	srlx	%g2,%i3,%i4
+	sllx	%g3,%i5,%g1
+
+	ldx	[%i1+16],%g2
+	srlx	%g3,%i3,%l4
+	or	%i4,%g1,%i4
+	stx	%i4,[%i0-32]
+	sllx	%g2,%i5,%g1
+
+	ldx	[%i1+24],%g3
+	srlx	%g2,%i3,%i4
+	or	%l4,%g1,%l4
+	stx	%l4,[%i0-24]
+	sllx	%g3,%i5,%g1
+
+	ldx	[%i1+32],%g2
+	srlx	%g3,%i3,%l4
+	or	%i4,%g1,%i4
+	stx	%i4,[%i0-16]
+	sllx	%g2,%i5,%g1
+
+	add	%i1,32,%i1
+	or	%l4,%g1,%l4
+	brnz	%i2,.Loop
+	 stx	%l4,[%i0-8]
+
+.Lend:	srlx	%g2,%i3,%g2
+	stx	%g2,[%i0-0]
+
+	mov	%l1,%i0
+	jmpl	%i7+8,%g0
+	 restore
+
+END(__mpn_rshift)
diff --git a/sysdeps/sparc64/sub_n.S b/sysdeps/sparc64/sub_n.S
new file mode 100644
index 0000000..93f8a82
--- /dev/null
+++ b/sysdeps/sparc64/sub_n.S
@@ -0,0 +1,55 @@
+/* SPARC v9 __mpn_sub_n -- Subtract two limb vectors of the same length > 0
+   and store difference in a third limb vector.
+
+   Copyright (C) 1995, 1996 Free Software Foundation, Inc.
+
+   This file is part of the GNU MP Library.
+
+   The GNU MP Library is free software; you can redistribute it and/or modify
+   it under the terms of the GNU Library General Public License as published by
+   the Free Software Foundation; either version 2 of the License, or (at your
+   option) any later version.
+
+   The GNU MP Library is distributed in the hope that it will be useful, but
+   WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+   or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
+   License for more details.
+
+   You should have received a copy of the GNU Library General Public License
+   along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
+   the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+   MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+/* INPUT PARAMETERS
+   res_ptr	%o0
+   s1_ptr	%o1
+   s2_ptr	%o2
+   size		%o3  */
+
+ENTRY(__mpn_sub_n)
+
+	sub %g0,%o3,%g3
+	sllx %o3,3,%g1
+	add %o1,%g1,%o1			! make s1_ptr point at end
+	add %o2,%g1,%o2			! make s2_ptr point at end
+	add %o0,%g1,%o0			! make res_ptr point at end
+	mov 0,%o4			! clear carry variable
+	sllx %g3,3,%o5			! compute initial address index
+
+1:	ldx [%o2+%o5],%g1		! load s2 limb
+	add %g3,1,%g3			! increment loop count
+	ldx [%o1+%o5],%g2		! load s1 limb
+	addcc %g1,%o4,%g1		! add s2 limb and carry variable
+	movcc %xcc,0,%o4		! if carry-out, o4 was 1; clear it
+	subcc %g1,%g2,%g1		! subtract s1 limb from sum
+	stx %g1,[%o0+%o5]		! store result
+	add %o5,8,%o5			! increment address index
+	brnz,pt %g3,1b
+	 movcs %xcc,1,%o4		! if s1 subtract gave carry, record it
+
+	retl
+	 mov %o4,%o0
+
+END(__mpn_sub_n)
diff --git a/sysdeps/sparc64/submul_1.S b/sysdeps/sparc64/submul_1.S
new file mode 100644
index 0000000..3cc0e3b
--- /dev/null
+++ b/sysdeps/sparc64/submul_1.S
@@ -0,0 +1,87 @@
+/* SPARC v9 __mpn_submul_1 -- Multiply a limb vector with a single limb and
+   subtract the product from a second limb vector.
+
+   Copyright (C) 1996 Free Software Foundation, Inc.
+
+   This file is part of the GNU MP Library.
+
+   The GNU MP Library is free software; you can redistribute it and/or modify
+   it under the terms of the GNU Library General Public License as published by
+   the Free Software Foundation; either version 2 of the License, or (at your
+   option) any later version.
+
+   The GNU MP Library is distributed in the hope that it will be useful, but
+   WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+   or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
+   License for more details.
+
+   You should have received a copy of the GNU Library General Public License
+   along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
+   the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+   MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+
+/* INPUT PARAMETERS
+   res_ptr	o0
+   s1_ptr	o1
+   size		o2
+   s2_limb	o3  */
+
+ENTRY(__mpn_submul_1)
+	!#PROLOGUE#	0
+	save	%sp,-128,%sp
+	!#PROLOGUE#	1
+
+	sub	%g0,%i2,%o7
+	sllx	%o7,3,%g5
+	sub	%i1,%g5,%o3
+	sub	%i0,%g5,%o4
+	mov	0,%o0			! zero cy_limb
+
+	srl	%i3,0,%o1		! extract low 32 bits of s2_limb
+	srlx	%i3,32,%i3		! extract high 32 bits of s2_limb
+	mov	1,%o2
+	sllx	%o2,32,%o2		! o2 = 0x100000000
+
+	!   hi   !
+             !  mid-1 !
+             !  mid-2 !
+		 !   lo   !
+.Loop:
+	sllx	%o7,3,%g1
+	ldx	[%o3+%g1],%g5
+	srl	%g5,0,%i0		! zero hi bits
+	srlx	%g5,32,%g5
+	mulx	%o1,%i0,%i4		! lo product
+	mulx	%i3,%i0,%i1		! mid-1 product
+	mulx	%o1,%g5,%l2		! mid-2 product
+	mulx	%i3,%g5,%i5		! hi product
+	srlx	%i4,32,%i0		! extract high 32 bits of lo product...
+	add	%i1,%i0,%i1		! ...and add it to the mid-1 product
+	addcc	%i1,%l2,%i1		! add mid products
+	mov	0,%l0			! we need the carry from that add...
+	movcs	%xcc,%o2,%l0		! ...compute it and...
+	add	%i5,%l0,%i5		! ...add to bit 32 of the hi product
+	sllx	%i1,32,%i0		! align low bits of mid product
+	srl	%i4,0,%g5		! zero high 32 bits of lo product
+	add	%i0,%g5,%i0		! combine into low 64 bits of result
+	srlx	%i1,32,%i1		! extract high bits of mid product...
+	add	%i5,%i1,%i1		! ...and add them to the high result
+	addcc	%i0,%o0,%i0		! add cy_limb to low 64 bits of result
+	mov	0,%g5
+	movcs	%xcc,1,%g5
+	add	%o7,1,%o7
+	ldx	[%o4+%g1],%l1
+	subcc	%l1,%i0,%i0
+	movcs	%xcc,1,%g5
+	stx	%i0,[%o4+%g1]
+	brnz	%o7,.Loop
+	 add	%i1,%g5,%o0		! compute new cy_limb
+
+	mov	%o0,%i0
+	jmpl	%i7+8,%g0
+	 restore
+
+END(__mpn_submul_1)