2006-01-16 Paolo Bonzini <bonzini@gnu.org>

	* configure.in: Set with_gnu_as, with_gnu_ld, with_newlib earlier.
	Set md_exec_prefix.  Use ACX_CHECK_INSTALLED_TARGET_TOOL to find
	the assembler, linker and binutils.
	* configure: Regenerate.

config:
2006-01-16  Paolo Bonzini  <bonzini@gnu.org>

	* acx.m4 (NCN_STRICT_CHECK_TARGET_TOOLS): Test $with_build_time_tools.
	(ACX_PATH_SEP): New.
	(ACX_TOOL_DIRS): Move here from the gcc directory.
	(ACX_CHECK_INSTALLED_TARGET_TOOL): New.
	(GCC_TARGET_TOOL): Do not use a host tool if we found a target tool
	with a complete path in either $with_build_time_tools or $exec_prefix.

2 files changed, 165 insertions, 20 deletions

diff --git a/config/ChangeLog b/config/ChangeLog
index b3df9f3..553ee48 100644
--- a/config/ChangeLog
+++ b/config/ChangeLog
@@ -1,13 +1,17 @@
-2006-02-01  Paolo Bonzini  <bonzini@gnu.org>
+2006-01-26  Paolo Bonzini  <bonzini@gnu.org>
 
-        PR target/25259
-        * stdint.m4: New.
+	* acx.m4 (NCN_STRICT_CHECK_TARGET_TOOLS): Test $with_build_time_tools.
+	(ACX_PATH_SEP): New.
+	(ACX_TOOL_DIRS): Move here from the gcc directory.
+	(ACX_CHECK_INSTALLED_TARGET_TOOL): New.
+	(GCC_TARGET_TOOL): Do not use a host tool if we found a target tool
+	with a complete path in either $with_build_time_tools or $exec_prefix.
 
-2005-12-20  Paolo Bonzini  <bonzini@gnu.org>
+2006-01-02  Paolo Bonzini  <bonzini@gnu.org>
 
-	Revert Ada-related part of the previous change.
+        PR target/25259
+        * stdint.m4: New.
 
-	* mt-ppc-aix: Delete.
 2005-12-20  Paolo Bonzini  <bonzini@gnu.org>
 
         Revert Ada-related part of the previous change.
diff --git a/config/acx.m4 b/config/acx.m4
index c71f39b..9f0dd1e 100644
--- a/config/acx.m4
+++ b/config/acx.m4
@@ -104,7 +104,7 @@ test -n "$target_alias" && ncn_target_tool_prefix=$target_alias-
 
 ####
 # NCN_STRICT_CHECK_TOOLS(variable, progs-to-check-for,[value-if-not-found],[path])
-# Like plain AC_CHECK_TOOLS, but require prefix if build!=target.
+# Like plain AC_CHECK_TOOLS, but require prefix if build!=host.
 
 AC_DEFUN([NCN_STRICT_CHECK_TOOLS],
 [AC_REQUIRE([_NCN_TOOL_PREFIXES]) []dnl
@@ -135,17 +135,32 @@ fi
 
 AC_DEFUN([NCN_STRICT_CHECK_TARGET_TOOLS],
 [AC_REQUIRE([_NCN_TOOL_PREFIXES]) []dnl
-for ncn_progname in $2; do
-  if test -n "$ncn_target_tool_prefix"; then
-    AC_CHECK_PROG([$1], [${ncn_target_tool_prefix}${ncn_progname}], 
-                  [${ncn_target_tool_prefix}${ncn_progname}], , [$4])
-  fi
-  if test -z "$ac_cv_prog_$1" && test $build = $target ; then
-    AC_CHECK_PROG([$1], [${ncn_progname}], [${ncn_progname}], , [$4]) 
-  fi
-  test -n "$ac_cv_prog_$1" && break
-done
+if test -n "$with_build_time_tools"; then
+  for ncn_progname in $2; do
+    AC_MSG_CHECKING([for ${ncn_progname} in $with_build_time_tools])
+    if test -x $with_build_time_tools/$1; then
+      ac_cv_prog_$1=$with_build_time_tools/$1
+      AC_MSG_RESULT(yes)
+      break
+    else
+      AC_MSG_RESULT(no)
+    fi
+  done
+fi
 
+if test -z "$ac_cv_prog_$1"; then
+  for ncn_progname in $2; do
+    if test -n "$ncn_target_tool_prefix"; then
+      AC_CHECK_PROG([$1], [${ncn_target_tool_prefix}${ncn_progname}], 
+                    [${ncn_target_tool_prefix}${ncn_progname}], , [$4])
+    fi
+    if test -z "$ac_cv_prog_$1" && test $build = $target ; then
+      AC_CHECK_PROG([$1], [${ncn_progname}], [${ncn_progname}], , [$4]) 
+    fi
+    test -n "$ac_cv_prog_$1" && break
+  done
+fi
+  
 if test -z "$ac_cv_prog_$1" ; then
   ifelse([$3],[], [set dummy $2
   if test $build = $target ; then
@@ -155,6 +170,124 @@ if test -z "$ac_cv_prog_$1" ; then
   fi], [$1="$3"])
 fi
 ]) []dnl # NCN_STRICT_CHECK_TARGET_TOOLS
+  
+
+# Backported from Autoconf 2.5x; can go away when and if
+# we switch.  Put the OS path separator in $PATH_SEPARATOR.
+AC_DEFUN([ACX_PATH_SEP], [
+# The user is always right.
+if test "${PATH_SEPARATOR+set}" != set; then
+  echo "#! /bin/sh" >conf$$.sh
+  echo  "exit 0"   >>conf$$.sh
+  chmod +x conf$$.sh
+  if (PATH="/nonexistent;."; conf$$.sh) >/dev/null 2>&1; then
+    PATH_SEPARATOR=';'
+  else
+    PATH_SEPARATOR=: 
+  fi
+  rm -f conf$$.sh
+fi
+])
+
+
+AC_DEFUN([ACX_TOOL_DIRS], [
+AC_REQUIRE([ACX_PATH_SEP])
+if test "x$exec_prefix" = xNONE; then
+        if test "x$prefix" = xNONE; then
+                gcc_cv_tool_prefix=$ac_default_prefix
+        else
+                gcc_cv_tool_prefix=$prefix
+        fi
+else
+        gcc_cv_tool_prefix=$exec_prefix
+fi
+
+# If there is no compiler in the tree, use the PATH only.  In any
+# case, if there is no compiler in the tree nobody should use
+# AS_FOR_TARGET and LD_FOR_TARGET.
+if test x$host = x$build && test -f $srcdir/gcc/BASE-VER; then
+    gcc_version=`cat $srcdir/gcc/BASE-VER`
+    gcc_cv_tool_dirs="$gcc_cv_tool_prefix/libexec/gcc/$target_noncanonical/$gcc_version$PATH_SEPARATOR"
+    gcc_cv_tool_dirs="$gcc_cv_tool_dirs$gcc_cv_tool_prefix/libexec/gcc/$target_noncanonical$PATH_SEPARATOR"
+    gcc_cv_tool_dirs="$gcc_cv_tool_dirs/usr/lib/gcc/$target_noncanonical/$gcc_version$PATH_SEPARATOR"
+    gcc_cv_tool_dirs="$gcc_cv_tool_dirs/usr/lib/gcc/$target_noncanonical$PATH_SEPARATOR"
+    gcc_cv_tool_dirs="$gcc_cv_tool_dirs$gcc_cv_tool_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version$PATH_SEPARATOR"
+    gcc_cv_tool_dirs="$gcc_cv_tool_dirs$gcc_cv_tool_prefix/$target_noncanonical/bin$PATH_SEPARATOR"
+else
+    gcc_cv_tool_dirs=
+fi
+
+if test x$build = x$target && test -n "$md_exec_prefix"; then
+        gcc_cv_tool_dirs="$gcc_cv_tool_dirs$md_exec_prefix$PATH_SEPARATOR"
+fi
+
+]) []dnl # ACX_TOOL_DIRS
+
+# ACX_HAVE_GCC_FOR_TARGET
+# Check if the variable GCC_FOR_TARGET really points to a GCC binary.
+AC_DEFUN([ACX_HAVE_GCC_FOR_TARGET], [
+cat > conftest.c << \EOF
+#ifdef __GNUC__
+  gcc_yay;
+#endif
+EOF
+if ($GCC_FOR_TARGET -E conftest.c | grep gcc_yay) > /dev/null 2>&1; then
+  have_gcc_for_target=yes
+else
+  GCC_FOR_TARGET=${ncn_target_tool_prefix}gcc
+  have_gcc_for_target=no
+fi
+rm conftest.c
+])
+
+# ACX_CHECK_INSTALLED_TARGET_TOOL(VAR, PROG)
+# Searching for installed target binutils.  We need to take extra care,
+# else we may find the wrong assembler, linker, etc., and lose.
+#
+# First try --with-build-time-tools, if specified.
+#
+# For build != host, we ask the installed GCC for the name of the tool it
+# uses, and accept it if it is an absolute path.  This is because the
+# only good choice for a compiler is the same GCC version that is being
+# installed (or we couldn't make target libraries), and we assume that
+# on the host system we'll have not only the same GCC version, but also
+# the same binutils version.
+#
+# For build == host, search the same directories that the installed
+# compiler will search.  We used to do this for the assembler, linker,
+# and nm only; for simplicity of configuration, however, we extend this
+# criterion to tools (such as ar and ranlib) that are never invoked by
+# the compiler, to avoid mismatches.
+#
+# Also note we have to check MD_EXEC_PREFIX before checking the user's path
+# if build == target.  This makes the most sense only when bootstrapping,
+# but we also do so when build != host.  In this case, we hope that the
+# build and host systems will have similar contents of MD_EXEC_PREFIX.
+#
+# If we do not find a suitable binary, then try the user's path.
+
+AC_DEFUN([ACX_CHECK_INSTALLED_TARGET_TOOL], [
+AC_REQUIRE([ACX_TOOL_DIRS])
+AC_REQUIRE([ACX_HAVE_GCC_FOR_TARGET])
+if test -z "$ac_cv_path_$1" ; then
+  if test -n "$with_build_time_tools"; then
+    AC_MSG_CHECKING([for ${ncn_target_tool_prefix}${ncn_progname} in $with_build_time_tools])
+    $1=`cd $with_build_time_tools && pwd`/$1
+    ac_cv_path_$1=[$]$1
+    AC_MSG_RESULT([$ac_cv_path_$1])
+  elif test $build != $host && test $have_gcc_for_target = yes; then
+    $1=`$GCC_FOR_TARGET --print-prog-name=$2`
+    test [$]$1=$2 && $1=
+    ac_cv_path_$1=[$]$1
+  fi
+fi
+if test -z "$ac_cv_path_$1" ; then
+  AC_PATH_PROG([$1], [$2], [], [$gcc_cv_tool_dirs])
+fi
+if test -z "$ac_cv_path_$1" ; then
+  NCN_STRICT_CHECK_TARGET_TOOLS([$1], [$2])
+fi
+]) []dnl # ACX_CHECK_INSTALLED_TARGET_TOOL
 
 ###
 # AC_PROG_CPP_WERROR
@@ -300,8 +433,13 @@ dnl GCC_TARGET_TOOL(PROGRAM, TARGET-VAR, HOST-VAR, IN-TREE-TOOL, LANGUAGE)
 AC_DEFUN([GCC_TARGET_TOOL],
 [AC_MSG_CHECKING(where to find the target $1)
 if test "x${build}" != "x${host}" ; then
-  # Canadian cross, just use what we found
-  AC_MSG_RESULT(pre-installed)
+  if expr "x[$]$2" : "x/" > /dev/null; then
+    # We already found the complete path
+    AC_MSG_RESULT(pre-installed in `dirname [$]$2`)
+  else
+    # Canadian cross, just use what we found
+    AC_MSG_RESULT(pre-installed)
+  fi
 else
   ifelse([$4],,,
   [ok=yes
@@ -318,7 +456,10 @@ else
     # An in-tree tool is available and we can use it
     $2='$$r/$(HOST_SUBDIR)/$4'
     AC_MSG_RESULT(just compiled)
-  el])if test "x$target" = "x$host"; then
+  el])if expr "x[$]$2" : "x/" > /dev/null; then
+    # We already found the complete path
+    AC_MSG_RESULT(pre-installed in `dirname [$]$2`)
+  elif test "x$target" = "x$host"; then
     # We can use an host tool
     $2='$($3)'
     AC_MSG_RESULT(host tool)